Version bump to 1.0, wrt bug #492266

(Portage version: 2.1.13.1/cvs/Linux x86_64, signed Manifest commit with key 0x3A051746)

2 files changed, 71 insertions, 1 deletions

diff --git a/sys-apps/bleachbit/ChangeLog b/sys-apps/bleachbit/ChangeLog
index 60053ed7cc7c..f52a64452bff 100644
--- a/sys-apps/bleachbit/ChangeLog
+++ b/sys-apps/bleachbit/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/bleachbit
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/ChangeLog,v 1.16 2013/09/27 17:06:07 dastergon Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/ChangeLog,v 1.17 2013/12/08 17:01:11 dastergon Exp $
+
+*bleachbit-1.0 (08 Dec 2013)
+
+  08 Dec 2013; Pavlos Ratis <dastergon@gentoo.org> +bleachbit-1.0.ebuild:
+  Version bump to 1.0, wrt bug #492266
 
   27 Sep 2013; Pavlos Ratis <dastergon@gentoo.org> metadata.xml:
   add myself as a maintainer
diff --git a/sys-apps/bleachbit/bleachbit-1.0.ebuild b/sys-apps/bleachbit/bleachbit-1.0.ebuild
new file mode 100644
index 000000000000..dd9e3710e130
--- /dev/null
+++ b/sys-apps/bleachbit/bleachbit-1.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/bleachbit-1.0.ebuild,v 1.1 2013/12/08 17:01:11 dastergon Exp $
+
+EAPI=5
+
+PLOCALES="ar ast be bg bn bs ca cs da de el en_AU en_GB eo es et eu fa fi fo fr gl he hi hr hu hy ia id it ja ko ku ky lt ms
+my nb nds nl pl pt_BR pt ro ru se si sk sl sr sv ta te th tr ug uk uz vi zh_CN zh_TW"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 eutils l10n
+
+DESCRIPTION="Clean junk to free disk space and to maintain privacy"
+HOMEPAGE="http://bleachbit.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="dev-python/pygtk:2[$PYTHON_USEDEP]"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+DOCS=( README )
+
+python_prepare_all() {
+	rem_locale() {
+		rm "po/${1}.po" || die "removing of ${1}.po failed"
+	}
+
+	l10n_find_plocales_changes po "" ".po"
+	l10n_for_each_disabled_locale_do rem_locale
+
+	addpredict /root/.gnome2 #401981
+
+	# warning: key "Encoding" in group "Desktop Entry" is deprecated
+	sed -i -e '/Encoding/d' ${PN}.desktop || die
+
+	# choose correct Python implementation, bug #465254
+	sed -i -e 's/python/$(PYTHON)/g' po/Makefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use nls && emake -C po
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use nls && emake -C po DESTDIR="${D}" install
+
+	# http://bugs.gentoo.org/388999
+	insinto /usr/share/${PN}/cleaners
+	doins cleaners/*.xml
+
+	newbin ${PN}.py ${PN}
+	python_replicate_script "${D}/usr/bin/${PN}"
+
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+}