Version bump #187152 by Davide Pesavento and a live git ebuild!

(Portage version: 2.1.3.7)

5 files changed, 172 insertions, 1 deletions

diff --git a/sys-apps/iproute2/ChangeLog b/sys-apps/iproute2/ChangeLog
index 03b36d5683e5..1b24f78c1c8e 100644
--- a/sys-apps/iproute2/ChangeLog
+++ b/sys-apps/iproute2/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for sys-apps/iproute2
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.85 2007/05/15 21:34:05 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.86 2007/08/25 16:49:07 vapier Exp $
+
+*iproute2-9999 (25 Aug 2007)
+
+  25 Aug 2007; Mike Frysinger <vapier@gentoo.org> +iproute2-9999.ebuild:
+  Live git ebuild!
+
+*iproute2-2.6.22.20070710 (25 Aug 2007)
+
+  25 Aug 2007; Mike Frysinger <vapier@gentoo.org>
+  +iproute2-2.6.22.20070710.ebuild:
+  Version bump #187152 by Davide Pesavento.
 
   15 May 2007; Jeroen Roovers <jer@gentoo.org>
   iproute2-2.6.19.20061214.ebuild:
diff --git a/sys-apps/iproute2/files/digest-iproute2-2.6.22.20070710 b/sys-apps/iproute2/files/digest-iproute2-2.6.22.20070710
new file mode 100644
index 000000000000..59362c522f2f
--- /dev/null
+++ b/sys-apps/iproute2/files/digest-iproute2-2.6.22.20070710
@@ -0,0 +1,3 @@
+MD5 20ef2767896a0f156b6fbabd47936f79 iproute2-2.6.22-070710.tar.gz 410719
+RMD160 b11222506531e446d1c0b2e73440fa1d98031ceb iproute2-2.6.22-070710.tar.gz 410719
+SHA256 3c6b48af9e655e4f0a34c7718e288960a1dc84a3ac7eb726e855adb45fbd953a iproute2-2.6.22-070710.tar.gz 410719
diff --git a/sys-apps/iproute2/files/digest-iproute2-9999 b/sys-apps/iproute2/files/digest-iproute2-9999
new file mode 100644
index 000000000000..e69de29bb2d1
--- /dev/null
+++ b/sys-apps/iproute2/files/digest-iproute2-9999
diff --git a/sys-apps/iproute2/iproute2-2.6.22.20070710.ebuild b/sys-apps/iproute2/iproute2-2.6.22.20070710.ebuild
new file mode 100644
index 000000000000..22915a6a1029
--- /dev/null
+++ b/sys-apps/iproute2/iproute2-2.6.22.20070710.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-2.6.22.20070710.ebuild,v 1.1 2007/08/25 16:49:07 vapier Exp $
+
+inherit eutils toolchain-funcs
+
+MY_PV=${PV%.*}
+SNAP=${PV##*.}
+SNAP=${SNAP:2}
+DESCRIPTION="kernel routing and traffic control utilities"
+HOMEPAGE="http://linux-net.osdl.org/index.php/Iproute2"
+SRC_URI="http://developer.osdl.org/dev/iproute2/download/${PN}-${MY_PV}-${SNAP}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="atm berkdb minimal"
+
+RDEPEND="!minimal? ( berkdb? ( sys-libs/db ) )
+	atm? ( net-dialup/linux-atm )"
+DEPEND="${RDEPEND}
+	>=virtual/os-headers-2.4.21"
+
+S=${WORKDIR}
+
+pkg_setup() {
+	if use kernel_linux ; then
+		ewarn
+		ewarn "${PN} requires kernel support for Netlink (CONFIG_NETLINK)."
+		ewarn "This is only applies for kernels prior to 2.4.17"
+		ewarn
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i "s:-O2:${CFLAGS}:" Makefile || die "sed Makefile failed"
+
+	epatch "${FILESDIR}"/${PN}-2.6.16.20060323-build.patch #137574
+
+	# don't build arpd if USE=-berkdb #81660
+	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
+	# Multilib fixes
+	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
+	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
+		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
+	# Use correct iptables dir, #144265.
+	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
+		include/iptables.h
+}
+
+src_compile() {
+	echo -n 'TC_CONFIG_ATM:=' > Config
+	use atm \
+		&& echo 'y' >> Config \
+		|| echo 'n' >> Config
+
+	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
+	emake \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		|| die "make"
+}
+
+src_install() {
+	if use minimal ; then
+		into /
+		dosbin tc/tc || die "minimal"
+		return 0
+	fi
+
+	emake \
+		DESTDIR="${D}" \
+		SBINDIR=/sbin \
+		DOCDIR=/usr/share/doc/${PF} \
+		install \
+		|| die "make install failed"
+	if use berkdb ; then
+		dodir /var/lib/arpd
+		# bug 47482, arpd doesn't need to be in /sbin
+		dodir /usr/sbin
+		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
+	fi
+}
diff --git a/sys-apps/iproute2/iproute2-9999.ebuild b/sys-apps/iproute2/iproute2-9999.ebuild
new file mode 100644
index 000000000000..73ae39f51fc2
--- /dev/null
+++ b/sys-apps/iproute2/iproute2-9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.1 2007/08/25 16:49:07 vapier Exp $
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
+inherit eutils toolchain-funcs git
+
+DESCRIPTION="kernel routing and traffic control utilities"
+HOMEPAGE="http://linux-net.osdl.org/index.php/Iproute2"
+SRC_URI=""
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="atm berkdb minimal"
+
+RDEPEND="!minimal? ( berkdb? ( sys-libs/db ) )
+	atm? ( net-dialup/linux-atm )"
+DEPEND="${RDEPEND}
+	>=virtual/os-headers-2.4.21"
+
+src_unpack() {
+	git_src_unpack
+	cd "${S}"
+	sed -i "s:-O2:${CFLAGS}:" Makefile || die "sed Makefile failed"
+
+	epatch "${FILESDIR}"/${PN}-2.6.16.20060323-build.patch #137574
+
+	# don't build arpd if USE=-berkdb #81660
+	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
+	# Multilib fixes
+	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
+	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
+		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
+	# Use correct iptables dir, #144265.
+	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
+		include/iptables.h
+}
+
+src_compile() {
+	echo -n 'TC_CONFIG_ATM:=' > Config
+	use atm \
+		&& echo 'y' >> Config \
+		|| echo 'n' >> Config
+
+	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
+	emake \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		|| die "make"
+}
+
+src_install() {
+	if use minimal ; then
+		into /
+		dosbin tc/tc || die "minimal"
+		return 0
+	fi
+
+	emake \
+		DESTDIR="${D}" \
+		SBINDIR=/sbin \
+		DOCDIR=/usr/share/doc/${PF} \
+		install \
+		|| die "make install failed"
+	if use berkdb ; then
+		dodir /var/lib/arpd
+		# bug 47482, arpd doesn't need to be in /sbin
+		dodir /usr/sbin
+		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
+	fi
+}