Add lz4 support.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

3 files changed, 64 insertions, 1 deletions

diff --git a/sys-fs/squashfs-tools/ChangeLog b/sys-fs/squashfs-tools/ChangeLog
index e9b9acbb3655..84e92b5b757f 100644
--- a/sys-fs/squashfs-tools/ChangeLog
+++ b/sys-fs/squashfs-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/squashfs-tools
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/ChangeLog,v 1.95 2014/01/23 12:40:10 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/ChangeLog,v 1.96 2014/01/27 16:36:46 jer Exp $
+
+*squashfs-tools-4.2_p20140119-r1 (27 Jan 2014)
+
+  27 Jan 2014; Jeroen Roovers <jer@gentoo.org>
+  +squashfs-tools-4.2_p20140119-r1.ebuild, metadata.xml:
+  Add lz4 support.
 
 *squashfs-tools-4.2_p20140119 (23 Jan 2014)
 
diff --git a/sys-fs/squashfs-tools/metadata.xml b/sys-fs/squashfs-tools/metadata.xml
index e1c66a45635b..1e576aae7ef1 100644
--- a/sys-fs/squashfs-tools/metadata.xml
+++ b/sys-fs/squashfs-tools/metadata.xml
@@ -4,5 +4,6 @@
   <herd>livecd</herd>
   <use>
     <flag name="xz">Enable support for XZ ("LZMA2") compression using <pkg>app-arch/xz-utils</pkg></flag>
+    <flag name="lz4">Enable support for LZ4 compression using <pkg>app-arch/lz4</pkg></flag>
   </use>
 </pkgmetadata>
diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild
new file mode 100644
index 000000000000..1a739cdf62d3
--- /dev/null
+++ b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild,v 1.1 2014/01/27 16:36:46 jer Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Tool for creating compressed filesystem type squashfs"
+HOMEPAGE="http://squashfs.sourceforge.net"
+SRC_URI="http://dev.gentoo.org/~jer/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=" ~amd64"
+IUSE="+xz lzma lz4 lzo xattr"
+
+RDEPEND="
+	sys-libs/zlib
+	!xz? ( !lzo? ( sys-libs/zlib ) )
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo )
+	xattr? ( sys-apps/attr )
+	xz? ( app-arch/xz-utils )
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${P}/squashfs-tools"
+
+src_configure() {
+	# set up make command line variables in EMAKE_SQUASHFS_CONF
+	EMAKE_SQUASHFS_CONF=(
+		$(usex lzma LZMA_XZ_SUPPORT=1 LZMA_XS_SUPPORT=0)
+		$(usex lzo LZO_SUPPORT=1 LZO_SUPPORT=0)
+		$(usex lz4 LZ4_SUPPORT=1 LZ4_SUPPORT=0)
+		$(usex xattr XATTR_SUPPORT=1 XATTR_SUPPORT=0)
+		$(usex xz XZ_SUPPORT=1 XZ_SUPPORT=0)
+	)
+
+	tc-export CC
+}
+
+src_compile() {
+	emake ${EMAKE_SQUASHFS_CONF[@]}
+}
+
+src_install() {
+	dobin mksquashfs unsquashfs
+	dodoc ../README
+}
+
+pkg_postinst() {
+	ewarn "This version of mksquashfs requires a 2.6.29 kernel or better"
+	use xz &&
+		ewarn "XZ support requires a 2.6.38 kernel or better"
+}