1 files changed, 52 insertions, 0 deletions
diff --git a/media-libs/libpng/libpng-1.5.17-r15.ebuild b/media-libs/libpng/libpng-1.5.17-r15.ebuild
new file mode 100644
index 000000000000..8ac51861fea5
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.17-r15.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.17-r15.ebuild,v 1.1 2013/11/06 08:12:36 polynomial-c Exp $
+
+# this ebuild is only for the libpng15.so.15 SONAME for ABI compat
+
+EAPI=5
+
+inherit eutils libtool
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng"
+SLOT="1.5"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon"
+
+RDEPEND="sys-libs/zlib:=
+	!=media-libs/libpng-1.5*:0"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+pkg_setup() {
+	local _preserved_lib=${EROOT}/usr/$(get_libdir)/libpng15.so.15
+	[[ -e ${_preserved_lib} ]] && rm -f "${_preserved_lib}"
+}
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--enable-arm-neon=$(usex neon)
+}
+
+src_compile() {
+	emake libpng15.la
+}
+
+src_install() {
+	newlib.so .libs/libpng15.so.15.* libpng15.so.15
+}