1 files changed, 56 insertions, 0 deletions
diff --git a/net-wireless/crda/crda-1.1.3.ebuild b/net-wireless/crda/crda-1.1.3.ebuild
new file mode 100644
index 000000000000..d29443c12163
--- /dev/null
+++ b/net-wireless/crda/crda-1.1.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/crda/crda-1.1.3.ebuild,v 1.1 2013/01/19 02:36:11 zerochaos Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs python
+
+DESCRIPTION="Central Regulatory Domain Agent for wireless networks."
+HOMEPAGE="http://wireless.kernel.org/en/developers/Regulatory"
+SRC_URI="http://linuxwireless.org/download/crda/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND="dev-libs/openssl:0
+	dev-libs/libnl:3
+	net-wireless/wireless-regdb
+	>=virtual/udev-171"
+DEPEND="${RDEPEND}
+	dev-python/m2crypto
+	=dev-lang/python-2*
+	virtual/pkgconfig"
+
+src_prepare() {
+	python_convert_shebangs 2 utils/key2pub.py
+
+	sed -i \
+		-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		UDEV_RULE_DIR="$($(tc-getPKG_CONFIG) --variable=udevdir udev)/rules.d" \
+		REG_BIN=/usr/$(get_libdir)/crda/regulatory.bin \
+		USE_OPENSSL=1 \
+		CC="$(tc-getCC)" \
+		all_noverify V=1
+}
+
+src_test() {
+	emake USE_OPENSSL=1 CC="$(tc-getCC)" verify
+}
+
+src_install() {
+	emake \
+		UDEV_RULE_DIR="$($(tc-getPKG_CONFIG) --variable=udevdir udev)/rules.d" \
+		REG_BIN=/usr/$(get_libdir)/crda/regulatory.bin \
+		USE_OPENSSL=1 \
+		DESTDIR="${D}" \
+		install
+
+	keepdir /etc/wireless-regdb/pubkeys
+}