1 files changed, 59 insertions, 0 deletions
diff --git a/sys-cluster/corosync/corosync-1.4.3.ebuild b/sys-cluster/corosync/corosync-1.4.3.ebuild
new file mode 100644
index 000000000000..91a861304b5a
--- /dev/null
+++ b/sys-cluster/corosync/corosync-1.4.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/corosync/corosync-1.4.3.ebuild,v 1.1 2012/05/16 09:39:24 ultrabug Exp $
+
+EAPI=4
+
+inherit base autotools
+
+DESCRIPTION="OSI Certified implementation of a complete cluster engine"
+HOMEPAGE="http://www.corosync.org/"
+SRC_URI="ftp://ftp:${PN}.org@${PN}.org/downloads/${P}/${P}.tar.gz"
+
+LICENSE="BSD-2 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86 ~x86-fbsd"
+IUSE="doc infiniband ssl static-libs"
+
+RDEPEND="!sys-cluster/heartbeat
+	ssl? ( dev-libs/nss )
+	infiniband? (
+		sys-infiniband/libibverbs
+		sys-infiniband/librdmacm
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( sys-apps/groff )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-docs.patch"
+)
+
+DOCS=( README.recovery README.devmap SECURITY TODO AUTHORS )
+
+src_prepare() {
+	base_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	# appends lib to localstatedir automatically
+	# FIXME: install just shared libs --disable-static does not work
+	econf \
+		--localstatedir=/var \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable doc) \
+		$(use_enable ssl nss) \
+		$(use_enable infiniband rdma)
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	keepdir /var/lib/corosync
+	use static-libs || rm -rf "${D}"/usr/$(get_libdir)/*.a || die
+}