app-admin/osiris/osiris-1.5.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/osiris/osiris-1.5.2-r1.ebuild,v 1.1 2005/04/24 02:25:45 wormo Exp $

DESCRIPTION="File integrity verification system"
HOMEPAGE="http://osiris.shmoo.com/"
SRC_URI="http://osiris.shmoo.com/data/${P}.tar.gz"

LICENSE="OSIRIS"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE="mysql doc"

DEPEND="mysql? ( >=dev-db/mysql-3.23.54a )"

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i \
		-e "s:-O3 -fomit-frame-pointer:${CFLAGS}:" \
		src/crypto/*/Makefile || die "sed"
}

src_compile() {
	# Osiris provides the necessary gdbm source so that gdbm does not
	# need to be installed to use Osiris. If mysql is set as a USE
	# variable, Osiris will use mysql instead of gdbm.
	einfo "Osiris uses gdbm by default, and will use MySQL if \"mysql\""
	einfo "is set as a USE variable; it cannot be configured to use both."

	local myconf
	use mysql \
		&& myconf="${myconf} --enable-module=mysql" \
		&& sed -i -e "s:mysql.h:mysql/mysql.h:" ${S}/src/modules/module_mysql.c
	econf ${myconf} || die "./configure failed"

	emake || die "emake failed"
}

src_install() {
	make install DESTDIR="${D}" || die

	if use doc
	then
		insinto /usr/share/doc/${PF}
		dohtml docs/manual.html
		dodoc docs/manual.txt
		doins -r configs
	fi
}