blob: ae059e32677a3980a8148c4912f5a5d18931e8aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/pgbouncer/pgbouncer-1.5.4.ebuild,v 1.2 2013/07/19 00:55:04 titanofold Exp $
EAPI="5"
# Upstream has *way* broken tests.
RESTRICT="test"
inherit eutils user
DESCRIPTION="Lightweight connection pooler for PostgreSQL"
HOMEPAGE="http://pgfoundry.org/projects/pgbouncer/"
SRC_URI="mirror://postgresql/projects/pgFoundry/${PN}/${PN}/${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc libevent udns"
REQUIRED_USE="
libevent? ( !udns )
udns? ( !libevent )
"
RDEPEND="
>=sys-libs/glibc-2.10
libevent? ( >=dev-libs/libevent-2.0 )
udns? ( >=net-libs/udns-0.1 )
"
DEPEND="
${RDEPEND}
doc? (
app-text/docbook-xml-dtd:4.5
app-text/xmlto
>=app-text/asciidoc-8.4
)
"
pkg_setup() {
enewgroup postgres 70
enewuser postgres 70 /bin/bash /var/lib/postgresql postgres
enewuser pgbouncer -1 -1 -1 postgres
}
src_prepare() {
epatch "${FILESDIR}/pgbouncer-dirs.patch"
}
src_configure() {
# --enable-debug is only used to disable stripping
econf \
--docdir=/usr/share/doc/${PF} \
--enable-debug \
$(use_enable debug cassert) \
$(use_with libevent) \
$(use_with udns)
}
src_install() {
emake DESTDIR="${D}" install
dodoc AUTHORS
newconfd "${FILESDIR}/${PN}.confd" "${PN}"
newinitd "${FILESDIR}/${PN}.initd" "${PN}"
insinto /etc
doins etc/pgbouncer.ini
insinto /etc/logrotate.d
newins "${FILESDIR}/logrotate" pgbouncer
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]] ; then
einfo "Please read the config.txt for Configuration Directives"
einfo
einfo "For Administration Commands, see:"
einfo " man pgbouncer"
einfo
einfo "By default, PgBouncer does not have access to any database."
einfo "GRANT the permissions needed for your application and make sure that it"
einfo "exists in PgBouncer's auth_file."
fi
}
|
GitWeb