dev-games/vamos/vamos-0.7.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/vamos/vamos-0.7.1.ebuild,v 1.1 2013/02/08 19:23:44 mr_bones_ Exp $

EAPI=5
inherit eutils

DESCRIPTION="an automotive simulation framework"
HOMEPAGE="http://vamos.sourceforge.net/"
SRC_URI="mirror://sourceforge/vamos/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="static-libs"

RDEPEND="virtual/opengl
	virtual/glu
	media-libs/freeglut
	media-libs/libpng:0
	media-libs/libsdl[joystick,video]
	media-libs/openal
	media-libs/freealut"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-as-needed.patch \
		"${FILESDIR}"/${P}-gcc46.patch
}

src_configure() {
	econf \
		--disable-unit-tests \
		$(use_enable static-libs static)
}

src_install() {
	default
	dobin caelum/.libs/caelum
	newdoc caelum/README README.caelum
	dodoc AUTHORS ChangeLog README TODO
	prune_libtool_files
}