dev-python/nose/nose-0.9.3-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/nose-0.9.3-r1.ebuild,v 1.5 2008/10/01 09:04:12 armin76 Exp $

NEED_PYTHON=2.2

inherit distutils eutils

KEYWORDS="~alpha amd64 ~ia64 ~sparc x86"

DESCRIPTION="An alternate test discovery and running process for unittest."
HOMEPAGE="http://somethingaboutorange.com/mrl/projects/nose/"
SRC_URI="http://somethingaboutorange.com/mrl/projects/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc examples twisted"

RDEPEND="dev-python/setuptools
	twisted? ( dev-python/twisted )"
DEPEND="${RDEPEND}
	doc? ( dev-python/docutils )"

src_unpack() {
	distutils_src_unpack

	# If twisted is in USE, disable twisted tests that access the network
	# else remove nose.twistedtools and related tests
	use twisted && epatch "${FILESDIR}/${P}-tests-nonetwork.patch"
	use twisted || rm nose/twistedtools.py unit_tests/test_twisted*
}

src_compile() {
	distutils_src_compile
	if use doc ; then
		PYTHONPATH=. scripts/mkindex.py
	fi
}

src_install() {
	DOCS="AUTHORS NEWS"
	distutils_src_install --install-data /usr/share

	use doc && dohtml index.html

	if use examples ; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}

src_test() {
	PYTHONPATH=. "${python}" setup.py test || die "test failed"
}