games-rpg/freedink/freedink-108.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/freedink/freedink-108.4.ebuild,v 1.1 2014/11/12 16:01:06 hasufell Exp $

EAPI=5

inherit games

DESCRIPTION="Dink Smallwood is an adventure/role-playing game, similar to Zelda (2D top view)"
HOMEPAGE="http://www.freedink.org/"
SRC_URI="mirror://gnu/freedink/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

DEPEND="
	>=media-libs/fontconfig-2.4
	>=media-libs/libsdl-1.2[X,sound,joystick,video]
	>=media-libs/sdl-gfx-2.0
	>=media-libs/sdl-image-1.2
	>=media-libs/sdl-mixer-1.2[midi,vorbis,wav]
	>=media-libs/sdl-ttf-2.0.9"
RDEPEND="${DEPEND}
	~games-rpg/freedink-data-1.08.20140901"
DEPEND="${DEPEND}
	dev-libs/check
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

src_prepare() {
	sed -i \
		-e 's#^datarootdir =.*$#datarootdir = /usr/share#' \
		share/Makefile.in || die
}

src_configure() {
	egamesconf \
		--disable-embedded-resources \
		--localedir="/usr/share/locale" \
		$(use_enable nls)
}

src_install() {
	default
	dodoc TROUBLESHOOTING
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	einfo
	elog "optional dependencies:"
	elog "  games-util/dfarc (dmod installer and frontend)"
	einfo
}