kde-base/perlqt/perlqt-4.8.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/perlqt/perlqt-4.8.2.ebuild,v 1.1 2012/04/04 23:59:36 johu Exp $

EAPI=4

DECLARATIVE_REQUIRED="optional"
MULTIMEDIA_REQUIRED="optional"
OPENGL_REQUIRED="optional"
QTHELP_REQUIRED="optional"
KDE_REQUIRED="never"
KDE_SCM="git"
inherit kde4-base

DESCRIPTION="Qt Perl bindings"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug phonon qimageblitz qscintilla qwt webkit"

RDEPEND="
	>=dev-lang/perl-5.10.1
	dev-perl/List-MoreUtils
	$(add_kdebase_dep smokeqt 'declarative?,multimedia?,opengl?,phonon?,qimageblitz?,qscintilla?,qthelp?,qwt?,webkit?')
"
DEPEND=${RDEPEND}

# Split from kdebindings-perl in 4.7
add_blocker kdebindings-perl

PATCHES=(
	"${FILESDIR}/${PN}-4.7.2-vendor.patch"
	"${FILESDIR}/${PN}-4.8.1-tests.patch"
)

# more failures
RESTRICT=test

src_configure() {
	local mycmakeargs=(
		-DDISABLE_Qt3Support=ON
		$(cmake-utils_use_disable declarative QtDeclarative)
		$(cmake-utils_use_disable multimedia QtMultimedia)
		$(cmake-utils_use_disable opengl QtOpenGL)
		$(cmake-utils_use_with phonon)
		$(cmake-utils_use_with qimageblitz QImageBlitz)
		$(cmake-utils_use_with qscintilla QScintilla)
		$(cmake-utils_use_disable qthelp QtHelp)
		$(cmake-utils_use_disable qwt)
		$(cmake-utils_use_disable webkit QtWebKit)
	)
	kde4-base_src_configure
}

src_test() {
	PERL5LIB="${CMAKE_BUILD_DIR}/blib/arch:${CMAKE_BUILD_DIR}/blib/lib" kde4-base_src_test
}