media-video/xvideoservicethief/xvideoservicethief-2.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/xvideoservicethief/xvideoservicethief-2.4.ebuild,v 1.2 2010/04/23 08:55:09 hwoarang Exp $

EAPI=2

LANGS="br ca cs da de es fr gl hu it ja ko nl pl ro ru sv"

inherit eutils qt4-r2 versionator

MY_PV=$(replace_all_version_separators '_')
MY_P="xVST_${MY_PV}_src"

DESCRIPTION="Download (and convert) videos from various Web Video Services"
HOMEPAGE="http://xviservicethief.sourceforge.net/"
SRC_URI="mirror://sourceforge/xviservicethief/${MY_P}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc"

DEPEND="app-arch/unzip
	>=x11-libs/qt-gui-4.5.3:4
	>=x11-libs/qt-webkit-4.5.3:4
	doc? ( app-doc/doxygen )"
RDEPEND=">=x11-libs/qt-gui-4.5.3:4
	media-video/ffmpeg
	media-video/flvstreamer"

RES_NAME="xVST"

S="${WORKDIR}"

src_prepare() {
	# fix translations
	mv "${S}"/resources/translations/${RES_NAME}_cz.ts	"${S}"/resources/translations/${RES_NAME}_cs.ts
	mv "${S}"/resources/translations/${RES_NAME}_jp.ts	"${S}"/resources/translations/${RES_NAME}_ja.ts
	mv "${S}"/resources/translations/${RES_NAME}_du.ts	"${S}"/resources/translations/${RES_NAME}_nl.ts
	mv "${S}"/resources/translations/${RES_NAME}_kr.ts
	"${S}"/resources/transaltions/${RES_NAME}_ko.ts
	# fix plugins, language path
	sed -i -e "s/getApplicationPath()\ +\ \"/\"\/usr\/share\/${PN}/g" \
		"${S}"/src/options.cpp || die "failed to fix paths"
}

src_compile() {
	local lang=
	emake || die "emake failed"
	for lang in "${S}"/resources/translations/*.ts; do
		lrelease ${lang}
	done
}

src_install() {
	dobin bin/xvst || die "dobin failed"
	local dest=/usr/share/${PN}/plugins
	dodir ${dest}
	find resources/services -name '*.js' -exec cp -dpR {} "${D}"${dest} \;
	newicon resources/images/InformationLogo.png xvst.png
	make_desktop_entry /usr/bin/xvst xVideoServiceThief xvst 'Qt;AudioVideo;Video'
	if use doc; then
		cd "${S}/documentation/source"
		sed -i "/OUTPUT_DIRECTORY/s:G\:.*:docs:" Doxyfile
		doxygen Doxyfile
		dohtml -r docs/html/* || die "dohtml failed"
	fi

	#install translations
	insinto /usr/share/${PN}/languages/
	local lang= tlang=
	for lang in ${LINGUAS}; do
		for tlang in ${LANGS}; do
			[[ ${lang} == ${tlang} ]] && doins "${S}"/resources/translations/xVST_${tlang}.qm
		done
	done
}