net-ftp/yafc/yafc-1.2.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/yafc/yafc-1.2.5.ebuild,v 1.1 2013/08/16 08:19:45 pinkbyte Exp $

EAPI=5

inherit bash-completion-r1 eutils

DESCRIPTION="Console ftp client with a lot of nifty features"
HOMEPAGE="http://www.yafc-ftp.com/"
SRC_URI="http://www.yafc-ftp.com/upload/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86"
IUSE="ipv6 readline kerberos socks5 ssh"

DEPEND="dev-libs/openssl:0
	readline? ( >=sys-libs/readline-6 )
	kerberos? ( virtual/krb5 )
	socks5? ( net-proxy/dante )
	ssh? ( net-libs/libssh )"
RDEPEND="${DEPEND}"

DOCS=( BUGS NEWS README THANKS TODO )

src_prepare() {
	epatch_user
}

src_configure() {
	export ac_cv_ipv6=$(usex ipv6)
	econf \
		$(use_with readline readline /usr) \
		$(use_with socks5 socks /usr) \
		$(use_with socks5 socks5 /usr) \
		$(use_with kerberos krb5) \
		$(use_with ssh) \
		--with-bash-completion="$(get_bashcompdir)" \
		--without-krb4
}

src_install() {
	default
	dodoc -r samples
}