net-proxy/httpush/httpush-0.9_beta11.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/httpush/httpush-0.9_beta11.ebuild,v 1.3 2006/02/13 15:02:40 mcummings Exp $

inherit eutils

MY_P="${P/_beta/b}"

DESCRIPTION="Httpush is an intercepting proxy, allowing user to modify HTTP requests on-the-fly"
HOMEPAGE="http://httpush.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE="xml2"

RDEPEND="dev-perl/URI
	virtual/perl-MIME-Base64
	dev-perl/libwww-perl
	dev-perl/Net-SSLeay
	dev-perl/Crypt-SSLeay
	dev-perl/HTML-Parser
	xml2? ( dev-perl/XML-Twig )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if ! useq xml2 ; then
		echo
		einfo "If you'd like to use httpush's learning mode, please CTRL-C now"
		einfo "and enable the xml2 USE flag."
		epause 3
		echo
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i 's:^\(require httpush;\)$:push @INC, "/usr/lib/httpush";\n\1:' \
		httpush.pl || die "sed INC failed"
	sed -i 's:^\(.*DATADIR="\)data\(.*\)$:\1/var/lib/httpush\2:' *.pl \
		lib/plugin/broker.pm || die "sed DATADIR= failed"
}

src_install() {
	keepdir /var/lib/httpush

	insinto /usr/lib/httpush
	doins -r httpush.{dtd,lck,pem,pm} lib

	insinto /usr/share/httpush/plugins
	doins plugins/*

	newbin httpush.pl httpush
	newbin reindex.pl reindex

	dodoc README ChangeLog LICENSE doc/*
}