net-wireless/kismet/kismet-2005.08.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/kismet/kismet-2005.08.1.ebuild,v 1.3 2005/08/16 21:34:23 anarchy Exp $

inherit linux-info

MY_P=${P/\./-}
MY_P=${MY_P/./-R}
S=${WORKDIR}/${MY_P}

DESCRIPTION="IEEE 802.11 wireless LAN sniffer"
HOMEPAGE="http://www.kismetwireless.net"
SRC_URI="http://www.kismetwireless.net/code/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ppc x86"
IUSE="gps ncurses"

RDEPEND="net-wireless/wireless-tools
		ncurses? ( sys-libs/ncurses )
		gps? ( app-misc/gpsdrive
				>=dev-libs/expat-1.95.4
				dev-libs/gmp
				>=media-gfx/imagemagick-6.0
				dev-perl/libwww-perl )"
DEPEND="${RDEPEND}
		>=sys-devel/autoconf-2.58
		sys-apps/sed"

src_unpack() {
	unpack ${A}

	sed -i -e "s:^\(logtemplate\)=\(.*\):\1=/tmp/\2:" \
		${S}/conf/kismet.conf.in
}

src_compile() {
	# the configure script only honors '--disable-foo'
	local config=""

	if ! use ncurses; then
		config="${config} --disable-curses --disable-panel"
	fi

	if ! use gps; then
		config="${config} --disable-gpsmap"
	fi

	econf \
		${config} \
		--with-linuxheaders=${KV_DIR}/include \
		|| die "econf failed"

	einfo "You may safely ignore the warning about the missing .depend file"
	emake dep || die "emake dep failed"
	emake || die "emake failed"
}

src_install () {
	emake DESTDIR=${D} install || die "emake install failed"

	dodoc CHANGELOG README TODO docs/*

	newinitd ${FILESDIR}/${P}-init.d kismet
	newconfd ${FILESDIR}/${P}-conf.d kismet
}