www-apps/nanoc/nanoc-3.7.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/nanoc/nanoc-3.7.5.ebuild,v 1.3 2015/01/25 09:53:45 graaff Exp $

EAPI=5
USE_RUBY="ruby19 ruby20 ruby21"

RUBY_FAKEGEM_EXTRADOC="ChangeLog NEWS.md README.md"

RUBY_FAKEGEM_TASK_DOC="doc"
RUBY_FAKEGEM_TASK_TEST="test:all"

inherit ruby-fakegem

DESCRIPTION="nanoc is a simple but very flexible static site generator written in Ruby"
HOMEPAGE="http://nanoc.ws/"
LICENSE="MIT"

KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="${IUSE} minimal"

DEPEND+="test? ( app-text/asciidoc app-text/highlight )"

ruby_add_rdepend "!minimal? (
	dev-ruby/mime-types
	dev-ruby/rack
)
	>=dev-ruby/cri-2.3:0"

ruby_add_bdepend "test? (
	>=dev-ruby/mocha-0.13
	dev-ruby/minitest
	=dev-ruby/rdoc-4*
	dev-ruby/systemu
	dev-ruby/yard
)
doc? (
	dev-ruby/kramdown
	dev-ruby/rdiscount
	dev-ruby/yard
)"

all_ruby_prepare() {
	use doc || use test || (rm tasks/doc.rake || die)
	use test || (rm tasks/test.rake || die)

	# Avoid dependency on coveralls.
	sed -i -e '/coverall/I s:^:#:' test/helper.rb || die

	# Avoid non-optional tests for w3c_validators which we don't have
	# packaged and which require network access.
	rm test/extra/checking/checks/test_{css,html}.rb || die

	# Skip a test that produces slightly different javascript.
	sed -i -e '/test_filter_with_options/,/^  end/ s:^:#:' test/filters/test_uglify_js.rb || die
}