1 files changed, 55 insertions, 0 deletions
diff --git a/sys-devel/gcc-config/gcc-config-1.8-r1.ebuild b/sys-devel/gcc-config/gcc-config-1.8-r1.ebuild
new file mode 100644
index 0000000..7416e6a
--- /dev/null
+++ b/sys-devel/gcc-config/gcc-config-1.8-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils unpacker toolchain-funcs multilib
+
+DESCRIPTION="utility to manage compilers"
+HOMEPAGE="https://gitweb.gentoo.org/proj/gcc-config.git/"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=sys-apps/gentoo-functions-0.10"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-1.8-dont_source_functions_sh_from_etc_initd.patch" # 504118
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		PV="${PV}" \
+		SUBLIBDIR="$(get_libdir)" \
+		install
+}
+
+pkg_postinst() {
+	# Scrub eselect-compiler remains
+	rm -f "${ROOT}"/etc/env.d/05compiler &
+
+	# Make sure old versions dont exist #79062
+	rm -f "${ROOT}"/usr/sbin/gcc-config &
+
+	# We not longer use the /usr/include/g++-v3 hacks, as
+	# it is not needed ...
+	rm -f "${ROOT}"/usr/include/g++{,-v3} &
+
+	# Do we have a valid multi ver setup ?
+	local x
+	for x in $(gcc-config -C -l 2>/dev/null | awk '$NF == "*" { print $2 }') ; do
+		gcc-config ${x}
+	done
+
+	wait
+}