And another round of GNOME 3.5.2 updates

svn path=/; revision=342

9 files changed, 396 insertions, 0 deletions

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
new file mode 100644
index 0000000..66a9af6
--- /dev/null
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -0,0 +1,3 @@
+DIST gnome-boxes-3.5.2.tar.xz 807496 RMD160 416d6964b916ce4ccea1580a44ff155204502b5e SHA1 7492471e5ac656f3d94a8dea509a0101518bccb1 SHA256 e0afe0f517acf0fdadba3b91eb5a938e585aca914d9801813b221b4e2a725ac8
+EBUILD gnome-boxes-3.5.2.ebuild 2090 RMD160 f914480c48bd129a6e2eee4f71f66ddcf6d57f9f SHA1 f5d519da1a2eff916cf9318e7f736a9aa59119de SHA256 5577cf81dc40e0ccaa7410c18e9a78b729d3b1183b8720695acb47994e176a1b
+EBUILD gnome-boxes-9999.ebuild 2069 RMD160 f2aed9e1093e4540e7819364f21d531317ccfbbd SHA1 c3e5ac48162d985b0d13f55ea0851e07d982c52b SHA256 1fea93a222e6d27d09f1498617be2beaa67b9bb0c98f89dfd32c96507013df4f
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-3.5.2.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-3.5.2.ebuild
new file mode 100644
index 0000000..da1fd28
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-3.5.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+GCONF_DEBUG="no"
+
+inherit linux-info gnome2
+if [[ ${PV} = 9999 ]]; then
+	inherit gnome2-live
+fi
+
+DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
+HOMEPAGE="https://live.gnome.org/Design/Apps/Boxes"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="bindist"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64" # qemu-kvm[spice] is 64bit-only
+fi
+
+# CHECK: We're hard-depending on qemu-kvm[spice]. Does app-emulation/qemu
+# support spice or not?
+# NOTE: sys-fs/* stuff is called via exec()
+RDEPEND="
+	>=dev-libs/libxml2-2.7.8:2
+	>=sys-fs/udev-165[gudev]
+	>=dev-libs/glib-2.29.90:2
+	>=dev-libs/gobject-introspection-0.9.6
+	>=sys-libs/libosinfo-0.1.1
+	app-emulation/qemu-kvm[spice]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/libvirt-glib-0.0.8
+	>=x11-libs/gtk+-3.3.5:3
+	>=net-libs/gtk-vnc-0.4.4[gtk3]
+	>=net-misc/spice-gtk-0.9[gtk3]
+	>=app-misc/tracker-0.14[iso]
+	>=gnome-base/libgnomekbd-3
+
+	sys-fs/fuse
+	sys-fs/fuseiso
+	sys-fs/mtools"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig"
+
+if [[ ${PV} = 9999 ]]; then
+	DEPEND="${DEPEND}
+		>=dev-lang/vala-0.14.0:0.14
+		sys-libs/libosinfo[introspection,vala]
+		app-emulation/libvirt-glib[introspection,vala]
+		net-libs/gtk-vnc[introspection,vala]
+		net-misc/spice-gtk[introspection,vala]"
+fi
+
+pkg_pretend() {
+	linux_config_exists
+
+	if ! { linux_chkconfig_present KVM_AMD || \
+		linux_chkconfig_present KVM_INTEL; }; then
+		ewarn "You need KVM support in your kernel to use GNOME Boxes!"
+	fi
+}
+
+pkg_setup() {
+	DOCS="AUTHORS README NEWS THANKS TODO"
+	G2CONF="--disable-schemas-compile
+		--disable-strict-cc
+		$(use_enable !bindist logos)
+		VALAC=$(type -P valac-0.14)"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	elog "Before running gnome-boxes, you will need to load the KVM modules"
+	elog "If you have an Intel Processor, run:"
+	elog "	modprobe kvm-intel"
+	einfo
+	elog "If you have an AMD Processor, run:"
+	elog "	modprobe kvm-amd"
+}
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-9999.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-9999.ebuild
new file mode 100644
index 0000000..57fac3c
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-9999.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+GCONF_DEBUG="no"
+
+inherit linux-info gnome2
+if [[ ${PV} = 9999 ]]; then
+	inherit gnome2-live
+fi
+
+DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
+HOMEPAGE="https://live.gnome.org/Design/Apps/Boxes"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="bindist"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64" # qemu-kvm[spice] is 64bit-only
+fi
+
+# CHECK: We're hard-depending on qemu-kvm[spice]. Does app-emulation/qemu
+# support spice or not?
+# NOTE: sys-fs/* stuff is called via exec()
+RDEPEND="
+	>=dev-libs/libxml2-2.7.8:2
+	>=sys-fs/udev-165[gudev]
+	>=dev-libs/glib-2.29.90:2
+	>=dev-libs/gobject-introspection-0.9.6
+	>=sys-libs/libosinfo-0.1.1
+	app-emulation/qemu-kvm[spice]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/libvirt-glib-0.0.7
+	>=x11-libs/gtk+-3.3.5:3
+	>=net-libs/gtk-vnc-0.4.4[gtk3]
+	>=net-misc/spice-gtk-0.9[gtk3]
+	>=app-misc/tracker-0.14[iso]
+	>=gnome-base/libgnomekbd-3
+
+	sys-fs/fuse
+	sys-fs/fuseiso
+	sys-fs/mtools"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig"
+
+if [[ ${PV} = 9999 ]]; then
+	DEPEND="${DEPEND}
+		>=dev-lang/vala-0.14.0:0.14
+		sys-libs/libosinfo[introspection,vala]
+		app-emulation/libvirt-glib[introspection,vala]
+		net-libs/gtk-vnc[introspection,vala]
+		net-misc/spice-gtk[introspection,vala]"
+fi
+
+pkg_pretend() {
+	linux_config_exists
+
+	if ! { linux_chkconfig_present KVM_AMD || \
+		linux_chkconfig_present KVM_INTEL; }; then
+		ewarn "You need KVM support in your kernel to use GNOME Boxes!"
+	fi
+}
+
+pkg_setup() {
+	DOCS="AUTHORS README NEWS THANKS TODO"
+	G2CONF="--disable-schemas-compile
+		--disable-strict-cc
+		$(use_enable !bindist logos)
+		VALAC=$(type -P valac-0.14)"
+}
+
+pkg_postinst() {
+	elog "Before running gnome-boxes, you will need to load the KVM modules"
+	elog "If you have an Intel Processor, run:"
+	elog "	modprobe kvm-intel"
+	einfo
+	elog "If you have an AMD Processor, run:"
+	elog "	modprobe kvm-amd"
+}
diff --git a/gnome-extra/gnome-color-manager/Manifest b/gnome-extra/gnome-color-manager/Manifest
new file mode 100644
index 0000000..422b160
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/Manifest
@@ -0,0 +1,2 @@
+DIST gnome-color-manager-3.5.1.tar.xz 2535212 RMD160 aceef2ef0731f87e2dcb643764935286651d2f8e SHA1 6854ccf4a53aa92eddd4f2316852d65b014da2ab SHA256 0851dd97493401a1f4856432e0ffcd3565864377a9ad23255c6122dee9b4fdf6
+EBUILD gnome-color-manager-3.5.1.ebuild 1787 RMD160 01ce562dde41fb57569b5363c8487d98d55ad712 SHA1 0cd0132c869ce2a4a793a9a8b33cad52a0795790 SHA256 6d1cdb6dd75a958456951d51f0aadab12e48660b2398c83ae12d68656952813b
diff --git a/gnome-extra/gnome-color-manager/gnome-color-manager-3.5.1.ebuild b/gnome-extra/gnome-color-manager/gnome-color-manager-3.5.1.ebuild
new file mode 100644
index 0000000..0e443c5
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/gnome-color-manager-3.5.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/gnome-color-manager-3.4.0.ebuild,v 1.1 2012/05/13 23:36:49 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Color profile manager for the GNOME desktop"
+HOMEPAGE="http://projects.gnome.org/gnome-color-manager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clutter packagekit raw"
+
+# FIXME: fix detection of docbook2man
+COMMON_DEPEND=">=dev-libs/glib-2.31.10:2
+	gnome-base/gnome-desktop:3
+	>=media-libs/lcms-2.2:2
+	>=media-libs/libcanberra-0.10[gtk3]
+	media-libs/libexif
+	media-libs/tiff
+
+	x11-libs/libX11
+	x11-libs/libXrandr
+	>=x11-libs/gtk+-2.91:3
+	>=x11-libs/vte-0.25.1:2.90
+	>=x11-misc/colord-0.1.12
+
+	clutter? (
+		>=media-libs/clutter-1.9.11:1.0
+		media-libs/clutter-gtk:1.0
+		media-libs/mash:0.2 )
+	packagekit? ( app-admin/packagekit-base )
+	raw? ( media-gfx/exiv2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-gfx/shared-color-profiles
+"
+# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	app-text/gnome-doc-utils
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+"
+
+# FIXME: run test-suite with files on live file-system
+RESTRICT="test"
+
+pkg_setup() {
+	# Always enable tests since they are check_PROGRAMS anyway
+	G2CONF="${G2CONF}
+		--disable-static
+		--disable-schemas-compile
+		--disable-scrollkeeper
+		--enable-tests
+		$(use_enable clutter)
+		$(use_enable packagekit)
+		$(use_enable raw exiv)"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "If you want to do display or scanner calibration, you will need to"
+	elog "install media-gfx/argyllcms"
+}
diff --git a/www-client/epiphany/Manifest b/www-client/epiphany/Manifest
new file mode 100644
index 0000000..53c5abc
--- /dev/null
+++ b/www-client/epiphany/Manifest
@@ -0,0 +1,4 @@
+AUX epiphany-3.3.90-paxctl-introspection.patch 835 RMD160 6b0e132afe80028e0ca66ace51bafe71fe2344c7 SHA1 bad74a12b1f4636bc38f77109e36389899a8ff39 SHA256 c7670baab442a5475e33a614d2f71fb4601398a1fc1bc898e6b9359d35d3d6b3
+AUX paxctl.sh 787 RMD160 1944c6ad29d556674a2aab18115d06c2e4842216 SHA1 45475a30566efbe674eeed341dc8e2932b3c732e SHA256 f55473f2b044d25598195b6676175bad9531d4374fff65505d7c717d90d0897e
+DIST epiphany-3.5.1.tar.xz 2581752 RMD160 e17466dd4482c2e3f013b317267432690dbba1b1 SHA1 795e722859bfacb6bb26b85607e7224a741a07d7 SHA256 abf9b615c83062e992dbdce61896a907f09cd8c71b29d0eee89781a2c936d5a2
+EBUILD epiphany-3.5.1.ebuild 2627 RMD160 361879b139005d53705e1e736ca8eaf986375553 SHA1 674cbaae433fb84f8f82e5037cfa570c5d34abe2 SHA256 7d4d853560fd1a5955f1ed74a534687ae029ad06ffa4719cfcab0cbd6e512e6d
diff --git a/www-client/epiphany/epiphany-3.5.1.ebuild b/www-client/epiphany/epiphany-3.5.1.ebuild
new file mode 100644
index 0000000..5277c3c
--- /dev/null
+++ b/www-client/epiphany/epiphany-3.5.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.4.2.ebuild,v 1.2 2012/05/19 21:58:10 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+
+inherit autotools eutils gnome2 pax-utils versionator virtualx
+if [[ ${PV} = 9999 ]]; then
+	inherit gnome2-live
+fi
+
+DESCRIPTION="GNOME webbrowser based on Webkit"
+HOMEPAGE="http://projects.gnome.org/epiphany/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="avahi doc +introspection +jit +nss test"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# XXX: Should we add seed support? Seed seems to be unmaintained now.
+RDEPEND="
+	>=dev-libs/glib-2.31.2:2
+	>=x11-libs/gtk+-3.3.14:3[introspection?]
+	>=dev-libs/libxml2-2.6.12:2
+	>=dev-libs/libxslt-1.1.7
+	>=app-text/iso-codes-0.35
+	>=net-libs/webkit-gtk-1.7.92:3[introspection?]
+	>=net-libs/libsoup-gnome-2.37.1:2.4
+	>=gnome-base/gnome-keyring-2.26.0
+	>=gnome-base/gsettings-desktop-schemas-0.0.1
+	>=x11-libs/libnotify-0.5.1
+
+	dev-db/sqlite:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+
+	x11-themes/gnome-icon-theme
+	x11-themes/gnome-icon-theme-symbolic
+
+	avahi? ( >=net-dns/avahi-0.6.22 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	!jit? ( net-libs/webkit-gtk[-jit] )
+	nss? ( dev-libs/nss )"
+# paxctl needed for bug #407085
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	jit? ( sys-apps/paxctl )
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
+	G2CONF="${G2CONF}
+		--enable-shared
+		--disable-schemas-compile
+		--disable-scrollkeeper
+		--disable-static
+		--with-distributor-name=Gentoo
+		$(use_enable avahi zeroconf)
+		$(use_enable introspection)
+		$(use_enable nss)
+		$(use_enable test tests)"
+}
+
+src_prepare() {
+	# Build-time segfaults under PaX with USE=introspection when building
+	# against webkit-gtk[introspection,jit]
+	if use introspection && use jit; then
+		epatch "${FILESDIR}/${PN}-3.3.90-paxctl-introspection.patch"
+		cp "${FILESDIR}/paxctl.sh" "${S}/" || die
+		eautoreconf
+	fi
+	gnome2_src_prepare
+}
+
+src_compile() {
+	# needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
+	unset DISPLAY
+	gnome2_src_compile
+}
+
+src_test() {
+	# FIXME: this should be handled at eclass level
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+
+	use jit && pax-mark m $(list-paxables tests/test*) #415801
+	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
+}
+
+src_install() {
+	gnome2_src_install
+	use jit && pax-mark m "${ED}usr/bin/epiphany"
+}
diff --git a/www-client/epiphany/files/epiphany-3.3.90-paxctl-introspection.patch b/www-client/epiphany/files/epiphany-3.3.90-paxctl-introspection.patch
new file mode 100644
index 0000000..f9e0616
--- /dev/null
+++ b/www-client/epiphany/files/epiphany-3.3.90-paxctl-introspection.patch
@@ -0,0 +1,24 @@
+From 1eee9260eba23a7fc17df49c5a0e24a99f88482a Mon Sep 17 00:00:00 2001
+From: Alexandre Rostovtsev <tetromino@gentoo.org>
+Date: Sun, 4 Mar 2012 21:55:20 -0500
+Subject: [PATCH] Add PaX marking to allow building introspection under PaX
+
+---
+ src/Makefile.am |    1 +
+ 1 files changed, 1 insertions(+), 0 deletions(-)
+
+diff --git a/src/Makefile.am b/src/Makefile.am
+index d6bf77f..ce52591 100644
+--- a/src/Makefile.am
++++ b/src/Makefile.am
+@@ -277,6 +277,7 @@ EPHY_GIR_C_FILES = \
+ 
+ Epiphany-$(EPIPHANY_API_VERSION).gir: $(INTROSPECTION_SCANNER) $(EPHY_GIR_H_FILES) \
+                                       $(EPHY_GIR_C_FILES) epiphany
++	bash $(top_srcdir)/paxctl.sh -m ./epiphany
+ 	$(AM_V_GEN) PKG_CONFIG_PATH=$(top_builddir)/data:$$PKG_CONFIG_PATH \
+ 	$(INTROSPECTION_SCANNER) -v --warn-all \
+ 		--identifier-prefix=Ephy \
+-- 
+1.7.8.5
+
diff --git a/www-client/epiphany/files/paxctl.sh b/www-client/epiphany/files/paxctl.sh
new file mode 100755
index 0000000..bb1b6e0
--- /dev/null
+++ b/www-client/epiphany/files/paxctl.sh
@@ -0,0 +1,24 @@
+#!/bin/bash
+# PaX marking code stolen from pax-utils.eclass
+
+flags=${1//-}; shift
+
+if type -p paxctl > /dev/null; then
+	echo "PT PaX marking -${flags} $@"
+	for f in "$@"; do
+		# First, try modifying the existing PAX_FLAGS header
+		paxctl -q${flags} "${f}" && continue
+		# Second, try stealing the (unused under PaX) PT_GNU_STACK header
+		paxctl -qc${flags} "${f}" && continue
+		# Third, try pulling the base down a page, to create space and
+		# insert a PT_GNU_STACK header (works on ET_EXEC)
+		paxctl -qC${flags} "${f}" && continue
+	done
+elif type -p scanelf > /dev/null; then
+	# Try scanelf, the Gentoo swiss-army knife ELF utility
+	# Currently this sets PT if it can, no option to control what it does.
+	echo "Fallback PaX marking -${flags} $@"
+	scanelf -Xxz ${flags} "$@"
+fi
+
+exit 0