blob: d2c0c654538221e22f794777ce7fe05b1c9583b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=5
EGIT_BRANCH="next"
EGIT_PROJECT="flightgear.git"
inherit games cmake-utils git-2
DESCRIPTION="Open Source Flight Simulator"
HOMEPAGE="http://www.flightgear.org/"
EGIT_REPO_URI="git://gitorious.org/fg/flightgear.git
git://mapserver.flightgear.org/flightgear/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug fgcom fgpanel +jsbsim oldfdm test +udev +yasim"
COMMON_DEPEND="
dev-db/sqlite:3
>=dev-games/openscenegraph-3.2[png]
>=dev-games/simgear-9999[-headless]
sys-libs/zlib
virtual/opengl
udev? ( virtual/udev )
fgpanel? (
media-libs/freeglut
media-libs/libpng
)
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/boost-1.37
media-libs/openal
>=media-libs/plib-1.8.5
"
RDEPEND="${COMMON_DEPEND}"
DOCS=(AUTHORS ChangeLog NEWS README Thanks)
src_configure() {
local mycmakeargs=(
-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
-DFG_DATA_DIR="${GAMES_DATADIR}"/${PN}-live
-DENABLE_FGADMIN=OFF
-DENABLE_PROFILE=OFF
-DENABLE_RTI=OFF
-DSIMGEAR_SHARED=ON
-DSP_FDMS=OFF
-DSYSTEM_SQLITE=ON
$(cmake-utils_use_enable fgcom)
$(cmake-utils_use_enable fgcom IAX)
$(cmake-utils_use_with fgpanel)
$(cmake-utils_use_enable jsbsim)
$(cmake-utils_use_enable oldfdm LARCSIM)
$(cmake-utils_use_enable oldfdm UIUC_MODEL)
$(cmake-utils_use_enable test LOGGING)
$(cmake-utils_use_enable test TESTS)
$(cmake-utils_use udev EVENT_INPUT)
$(cmake-utils_use_enable yasim)
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
doicon -s scalable icons/scalable/flightgear.svg
newmenu package/${PN}.desktop ${PN}.desktop
prepgamesdirs
}
pkg_postinst() {
elog "FlightGear is now installed, but to run it you"
elog "have to download fgdata as well, which is expected under"
elog "${GAMES_DATADIR}/${PN}-live"
elog
elog "You can save it anywhere else but then you have to set"
elog "FG_ROOT to that directory or create an \"--fg-root=\" entry in ~/.fgfsrc"
elog
elog "To download fgdata, use"
elog "\"git clone git://mapserver.flightgear.org/fgdata/ SOMEPATH\"."
elog
elog "Don't forget that before updating FlightGear you will most likely"
elog "have to update Simgear, too"
elog
elog
elog "It is recommended that you install a launcher,"
elog "as it provides easy access to startup options:"
elog "* games-simulation/fgrun"
}
|
GitWeb