kde-plasma/powerdevil: 5.26.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/kde-plasma/powerdevil/Manifest b/kde-plasma/powerdevil/Manifest
new file mode 100644
index 0000000000..1170f6e6fb
--- /dev/null
+++ b/kde-plasma/powerdevil/Manifest
@@ -0,0 +1 @@
+DIST powerdevil-5.26.90.tar.xz 784956 BLAKE2B 531271d2918457c4407616dd8df38c14c261fb432abcc4eca42df2b69f71e87201fcb653c15ceb66879528d21b533318b7614804eee65dd8a48c9f5b93c395b8 SHA512 483050483f0a72228713fc70a955a879af6ad461ad729370a3ad9d07d12f8f89683f3b0ea37e2dccfcb475f09eee8fb949ca4ff544077079f13a0f5096b20c87
diff --git a/kde-plasma/powerdevil/powerdevil-5.26.90.ebuild b/kde-plasma/powerdevil/powerdevil-5.26.90.ebuild
new file mode 100644
index 0000000000..00ff655eee
--- /dev/null
+++ b/kde-plasma/powerdevil/powerdevil-5.26.90.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.102.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.7
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://invent.kde.org/plasma/powerdevil"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="brightness-control caps +wireless"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5[policykit]
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	virtual/libudev:=
+	x11-libs/libxcb
+	brightness-control? ( app-misc/ddcutil:= )
+	caps? ( sys-libs/libcap )
+	wireless? (
+		>=kde-frameworks/bluez-qt-${KFMIN}:5
+		>=kde-frameworks/networkmanager-qt-${KFMIN}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=sys-power/upower-0.9.23
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_DDCUTIL=$(usex brightness-control)
+		$(cmake_use_find_package caps Libcap)
+		$(cmake_use_find_package wireless KF5BluezQt)
+		$(cmake_use_find_package wireless KF5NetworkManagerQt)
+	)
+
+	ecm_src_configure
+}