dev-ruby/railties: depend on the correct eselect-rails version

This fixes a problem where an older version of eselect-rails won't
recognize the newer rails versions.

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

2 files changed, 145 insertions, 0 deletions

diff --git a/dev-ruby/railties/railties-7.0.8.4-r1.ebuild b/dev-ruby/railties/railties-7.0.8.4-r1.ebuild
new file mode 100644
index 000000000000..40662c9295e3
--- /dev/null
+++ b/dev-ruby/railties/railties-7.0.8.4-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+RUBY_FAKEGEM_TASK_TEST="test:regular"
+RUBY_FAKEGEM_RECIPE_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="railties.gemspec"
+
+RUBY_FAKEGEM_BINDIR="exe"
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Tools for creating, working with, and running Rails applications"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+
+RUBY_S="rails-${PV}/${PN}"
+
+# The test suite has many failures, most likely due to a mismatch in
+# exact dependencies or environment specifics. Needs further
+# investigation.
+RESTRICT="test"
+
+RDEPEND+=">=app-eselect/eselect-rails-0.26"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	~dev-ruby/actionpack-${PV}
+	dev-ruby/thor:1
+	>=dev-ruby/rake-12.2
+	dev-ruby/method_source
+	>=dev-ruby/zeitwerk-2.5:2
+"
+
+ruby_add_bdepend "
+	test? (
+		~dev-ruby/actionview-${PV}
+		dev-ruby/mocha:0.14
+	)"
+
+all_ruby_prepare() {
+	rm "${S}/../Gemfile" || die "Unable to remove Gemfile"
+	sed -i -e '/load_paths/d' test/abstract_unit.rb || die "Unable to remove load paths"
+	sed -i -e '1igem "minitest", "~>4.0"' test/abstract_unit.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	ruby_fakegem_binwrapper rails rails-${PV}
+}
+
+pkg_postinst() {
+	elog "To select between slots of rails, use:"
+	elog "\teselect rails"
+
+	eselect rails update
+}
+
+pkg_postrm() {
+	eselect rails update
+}
diff --git a/dev-ruby/railties/railties-7.1.3.4-r1.ebuild b/dev-ruby/railties/railties-7.1.3.4-r1.ebuild
new file mode 100644
index 000000000000..7b7aab03a013
--- /dev/null
+++ b/dev-ruby/railties/railties-7.1.3.4-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_TASK_TEST="test:regular"
+RUBY_FAKEGEM_RECIPE_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="railties.gemspec"
+
+RUBY_FAKEGEM_BINDIR="exe"
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Tools for creating, working with, and running Rails applications"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+
+RUBY_S="rails-${PV}/${PN}"
+
+# The test suite has many failures, most likely due to a mismatch in
+# exact dependencies or environment specifics. Needs further
+# investigation.
+RESTRICT="test"
+
+RDEPEND+=">=app-eselect/eselect-rails-0.27"
+
+ruby_add_rdepend "
+	~dev-ruby/actionpack-${PV}
+	~dev-ruby/activesupport-${PV}
+	dev-ruby/irb
+	>=dev-ruby/rackup-1.0.0
+	>=dev-ruby/rake-12.2
+	>=dev-ruby/thor-1.2.2:1
+	>=dev-ruby/zeitwerk-2.6:2
+"
+
+ruby_add_bdepend "
+	test? (
+		~dev-ruby/actionview-${PV}
+		dev-ruby/mocha
+	)"
+
+all_ruby_prepare() {
+	rm "${S}/../Gemfile" || die "Unable to remove Gemfile"
+	sed -i -e '/load_paths/d' test/abstract_unit.rb || die "Unable to remove load paths"
+	sed -i -e '1igem "minitest", "~>4.0"' test/abstract_unit.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	ruby_fakegem_binwrapper rails rails-${PV}
+}
+
+pkg_postinst() {
+	elog "To select between slots of rails, use:"
+	elog "\teselect rails"
+
+	eselect rails update
+}
+
+pkg_postrm() {
+	eselect rails update
+}