media-libs/libavif: Add gdk-pixbuf use flag, add live ebuild

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Daniel Novomesky <dnovomesky@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/17690
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 120 insertions, 11 deletions

diff --git a/media-libs/libavif/libavif-0.8.1.ebuild b/media-libs/libavif/libavif-0.8.1.ebuild
index f7efdd4f83f6..95d3907fe7f8 100644
--- a/media-libs/libavif/libavif-0.8.1.ebuild
+++ b/media-libs/libavif/libavif-0.8.1.ebuild
@@ -3,27 +3,28 @@
 
 EAPI=7
 
-inherit cmake
+inherit cmake gnome2-utils
 
 DESCRIPTION="Library for encoding and decoding .avif files"
 HOMEPAGE="https://github.com/AOMediaCodec/libavif"
 SRC_URI="https://github.com/AOMediaCodec/libavif/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
-LICENSE="BSD"
+LICENSE="BSD-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="+aom dav1d examples extras rav1e"
+IUSE="+aom dav1d examples extras gdk-pixbuf rav1e"
 
 DEPEND="media-libs/libpng
 	sys-libs/zlib
 	virtual/jpeg
-	aom? ( media-libs/libaom )
+	aom? ( >=media-libs/libaom-2.0.0 )
 	dav1d? ( media-libs/dav1d )
-	rav1e? ( media-video/rav1e )"
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	rav1e? ( media-video/rav1e[capi] )"
 RDEPEND="${DEPEND}"
 BDEPEND="virtual/pkgconfig"
 
-REQUIRED_USE="|| ( aom dav1d rav1e )"
+REQUIRED_USE="|| ( aom dav1d )"
 
 src_configure() {
 	local mycmakeargs=(
@@ -40,7 +41,33 @@ src_configure() {
 		-DAVIF_BUILD_EXAMPLES=$(usex examples ON OFF)
 		-DAVIF_BUILD_APPS=$(usex extras ON OFF)
 		-DAVIF_BUILD_TESTS=$(usex extras ON OFF)
+
+		-DAVIF_BUILD_GDK_PIXBUF=$(usex gdk-pixbuf ON OFF)
 	)
 
 	cmake_src_configure
 }
+
+pkg_preinst() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_savelist
+	fi
+}
+
+pkg_postinst() {
+	if ! use aom && ! use rav1e ; then
+		ewarn "aom and rav1e flags are not set,"
+		ewarn "libavif will work in read-only mode."
+		ewarn "Enable aom or rav1e flag if you want to save .AVIF files."
+	fi
+
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}
+
+pkg_postrm() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}
diff --git a/media-libs/libavif/libavif-9999.ebuild b/media-libs/libavif/libavif-9999.ebuild
new file mode 100644
index 000000000000..ffaba14b1959
--- /dev/null
+++ b/media-libs/libavif/libavif-9999.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake git-r3 gnome2-utils
+
+DESCRIPTION="Library for encoding and decoding .avif files"
+HOMEPAGE="https://github.com/AOMediaCodec/libavif"
+EGIT_REPO_URI="https://github.com/AOMediaCodec/libavif.git"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="+aom dav1d examples extras gdk-pixbuf rav1e"
+
+DEPEND="media-libs/libpng
+	sys-libs/zlib
+	virtual/jpeg
+	aom? ( >=media-libs/libaom-2.0.0 )
+	dav1d? ( media-libs/dav1d )
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	rav1e? ( media-video/rav1e[capi] )"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="|| ( aom dav1d )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DAVIF_CODEC_AOM=$(usex aom ON OFF)
+		-DAVIF_CODEC_DAV1D=$(usex dav1d ON OFF)
+		-DAVIF_CODEC_LIBGAV1=OFF
+		-DAVIF_CODEC_RAV1E=$(usex rav1e ON OFF)
+
+		# Use system libraries.
+		-DAVIF_LOCAL_ZLIBPNG=OFF
+		-DAVIF_LOCAL_JPEG=OFF
+
+		-DAVIF_BUILD_EXAMPLES=$(usex examples ON OFF)
+		-DAVIF_BUILD_APPS=$(usex extras ON OFF)
+		-DAVIF_BUILD_TESTS=$(usex extras ON OFF)
+
+		-DAVIF_BUILD_GDK_PIXBUF=$(usex gdk-pixbuf ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+pkg_preinst() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_savelist
+	fi
+}
+
+pkg_postinst() {
+	if ! use aom && ! use rav1e ; then
+		ewarn "aom and rav1e flags are not set,"
+		ewarn "libavif will work in read-only mode."
+		ewarn "Enable aom or rav1e flag if you want to save .AVIF files."
+	fi
+
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}
+
+pkg_postrm() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}
diff --git a/media-libs/libavif/metadata.xml b/media-libs/libavif/metadata.xml
index 58fba5b72b3b..31ef145a4ce5 100644
--- a/media-libs/libavif/metadata.xml
+++ b/media-libs/libavif/metadata.xml
@@ -2,13 +2,22 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <maintainer type="person">
-  <email>juippis@gentoo.org</email>
-  <name>Joonas Niilola</name>
+    <email>juippis@gentoo.org</email>
+    <name>Joonas Niilola</name>
+  </maintainer>
+  <maintainer type="person">
+    <email>dnovomesky@gmail.com</email>
+    <name>Daniel Novomesky</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
   </maintainer>
   <use>
     <flag name="aom">Enable support for the AOM codec encoding and decoding</flag>
-    <flag name="dav1d">Enable support for the dav1d codec encoding and decoding</flag>
-    <flag name="extras">Build extra apps and test files</flag>
-    <flag name="rav1e">Enable support for the rav1e codec encoding and decoding</flag>
+    <flag name="dav1d">Enable support for the dav1d codec decoding</flag>
+    <flag name="extras">Build extra apps (avifenc, avifdec) and test files</flag>
+    <flag name="gdk-pixbuf">Build a gdk-pixbuf loader</flag>
+    <flag name="rav1e">Enable support for the rav1e codec encoding</flag>
   </use>
 </pkgmetadata>