media-fonts/noto-emoji: add 20241003

Also add back noto emoji monochrome version (upstream dropped it from the main
repo long time ago).

Thanks-to: Matteo Modesti
Closes: https://bugs.gentoo.org/943299
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/media-fonts/noto-emoji/Manifest b/media-fonts/noto-emoji/Manifest
index bb4c4e6c01ca..a19966f2b37b 100644
--- a/media-fonts/noto-emoji/Manifest
+++ b/media-fonts/noto-emoji/Manifest
@@ -1 +1,3 @@
 DIST noto-emoji-20231130.tar.gz 201447944 BLAKE2B da80f3b7b3a99cefa18cf34c6f55a3bb0e407d7f8df9927ae747ddc74625f9d08a5ba3118a908ffd7fe90edd90c45b4f9d23d44e6d0cd92779b2f5322346ae20 SHA512 310fac7eb9aa35065cbc030276ead6d1f9111059b0142143cfab2c9c48dd1106b1cce135a745681f57df95c0510cb04249532ed765edf881ed7ab31a38bd538a
+DIST noto-emoji-20241003-monochrome.tar.gz 2926925 BLAKE2B 6626457993435574338dc9c163bd59a792a8bd38e9a52c54af39a8cca0cf47dd2a15cc9a57b5d8918b07eaf0c72c628aa359d6474b6784e1eec79ad170d2f77b SHA512 18c8341d2b84760670d780e4795b1cd2d5a88f721806507817f896db6bbb738075f59d5317179a49af27bb1565e6e1f485a1513a8b4f1beb879689d44ab71f3f
+DIST noto-emoji-20241003.tar.gz 204137209 BLAKE2B 580cff6708f07a850d4309e21f5762bafb631437677eb21f5c125ef93c2b66b53f825ae4013b141e4c5b795b3ab6bf39cf7622e6a66fa2fe06b6795e0ac05ab6 SHA512 225eb18052242621690a81c97b30c65198600b15116d28e49d9757d36c85ead8da098994db0a4c1329fbe312a26e9a19261c71a156836d7d3e677622bf25c868
diff --git a/media-fonts/noto-emoji/noto-emoji-20241003.ebuild b/media-fonts/noto-emoji/noto-emoji-20241003.ebuild
new file mode 100644
index 000000000000..f41447ec816e
--- /dev/null
+++ b/media-fonts/noto-emoji/noto-emoji-20241003.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit font
+
+DESCRIPTION="Google Noto Emoji fonts"
+HOMEPAGE="https://fonts.google.com/noto/specimen/Noto+Color+Emoji https://fonts.google.com/noto/specimen/Noto+Emoji
+	https://github.com/googlefonts/noto-emoji https://github.com/zjaco13/Noto-Emoji-Monochrome"
+
+# https://github.com/googlefonts/noto-emoji/issues/441
+# https://github.com/googlefonts/noto-emoji/issues/390
+COMMIT="22e564626297b4df0a40570ad81d6c05cc7c38bd"
+COMMIT_MC="24d8485dc7eeda9ec8d08788dfacad75127aebc7"
+SRC_URI="https://github.com/googlefonts/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz
+	https://github.com/zjaco13/Noto-Emoji-Monochrome/archive/${COMMIT_MC}.tar.gz -> ${P}-monochrome.tar.gz"
+
+LICENSE="Apache-2.0 OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="icons"
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+# https://github.com/gentoo/gentoo/pull/32203
+FONT_CONF=( "${FILESDIR}"/75-noto-emoji-fallback.conf )
+
+src_compile() { :; }
+
+src_install() {
+	# Ensure we install only the desired font (the same other distros
+	# supply), https://bugs.gentoo.org/927294
+	FONT_S="${S}/fonts-install"
+
+	# Don't lose fancy emoji icons
+	if use icons; then
+		for i in 32 72 128 512; do
+			insinto "/usr/share/icons/${PN}/${i}/emotes/"
+			doins png/"${i}"/*.png
+		done
+
+		insinto /usr/share/icons/"${PN}"/scalable/emotes/
+		doins svg/*.svg
+	fi
+
+	# Ensure we install only the desired font (the same other distros
+	# supply), https://bugs.gentoo.org/927294
+	mkdir fonts-install || die
+	FONT_S="${S}/fonts-install"
+	cp -p fonts/NotoColorEmoji.ttf fonts-install/. || die
+	cp -p "${WORKDIR}"/Noto-Emoji-Monochrome-${COMMIT_MC}/fonts/*.ttf fonts-install/. || die
+
+	FONT_SUFFIX="ttf"
+	font_src_install
+
+	dodoc README.md
+}