app-backup/borgbackup: 1.1.10-r1, 9999: man pages added.

Closes: https://bugs.gentoo.org/639722
Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Piotr Karbowski <slashbeast@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/app-backup/borgbackup/borgbackup-1.1.10-r1.ebuild b/app-backup/borgbackup/borgbackup-1.1.10-r1.ebuild
new file mode 100644
index 000000000000..6b88a3e3c19c
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.1.10-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/borg.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="libressl"
+
+# Unfortunately we have a file conflict with app-office/borg, bug #580402
+RDEPEND="
+	!!app-office/borg
+	app-arch/lz4
+	virtual/acl
+	dev-python/llfuse[${PYTHON_USEDEP}]
+	~dev-python/msgpack-0.5.6[${PYTHON_USEDEP}]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+"
+
+DEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	${RDEPEND}
+"
+
+python_prepare_all() {
+	# allow use of new (renamed) msgpack
+	sed -i "s|'msgpack-python.*',||g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+}
diff --git a/app-backup/borgbackup/borgbackup-9999.ebuild b/app-backup/borgbackup/borgbackup-9999.ebuild
index e2ccd0dbba7c..81920946717e 100644
--- a/app-backup/borgbackup/borgbackup-9999.ebuild
+++ b/app-backup/borgbackup/borgbackup-9999.ebuild
@@ -47,3 +47,8 @@ python_prepare_all() {
 	sed -i "s|'msgpack-python.*',||g" setup.py || die
 	distutils-r1_python_prepare_all
 }
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+}