app-misc/g15composer: EAPI-7 revbump

- Fixed docdir

Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/app-misc/g15composer/g15composer-3.2-r1.ebuild b/app-misc/g15composer/g15composer-3.2-r1.ebuild
new file mode 100644
index 000000000000..9c316e0abb2c
--- /dev/null
+++ b/app-misc/g15composer/g15composer-3.2-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A library to render text and shapes into a buffer usable by the Logitech G15"
+HOMEPAGE="https://sourceforge.net/projects/g15tools/"
+SRC_URI="mirror://sourceforge/g15tools/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="truetype examples"
+
+DEPEND="app-misc/g15daemon
+	>=dev-libs/libg15render-1.2[truetype?]
+	truetype? ( media-libs/freetype	)"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-freetype_pkgconfig.patch"
+	"${FILESDIR}/${P}-docdir.patch"
+)
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable truetype ttf)
+}
+
+src_install() {
+	local DOCS=( AUTHORS README ChangeLog )
+	default
+
+	newinitd "${FILESDIR}/${P}.initd" ${PN}
+	newconfd "${FILESDIR}/${P}.confd" ${PN}
+
+	if use examples ; then
+		exeinto "/usr/share/${PN}"
+		doexe examples/*
+	fi
+}
+
+pkg_postinst() {
+	elog "Set the user to run g15composer in /etc/conf.d/g15composer before starting the service."
+}