app-misc/gramps: add 5.1.5

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/app-misc/gramps/Manifest b/app-misc/gramps/Manifest
index 92d6748a3c19..637148df657e 100644
--- a/app-misc/gramps/Manifest
+++ b/app-misc/gramps/Manifest
@@ -1 +1,2 @@
 DIST gramps-5.1.4.tar.gz 17425713 BLAKE2B 9b3761906b70ed6b85112e502290013cf421669418355ed0dc54d00adbcc2af4cd74c596bacaad50cdac6457e7a3b7675d4afb7b471fd471af8b7a6adae3ad82 SHA512 f43fc250142968331db1875260577e022898cff2d1453ee6b74be760d798b75cfdf93492d8d823dbb094da2ddd96a4f249e813c603e7cd9d0585641424284734
+DIST gramps-5.1.5.tar.gz 17425167 BLAKE2B f07fcb84c28f1def84c5568da6ac38a78def8657a0ee010163cb7e0899dd94ebb1c851e2c9d207fd9725754363ac7243a66f0de6e0d9708270d2d43c90485212 SHA512 8e36e8da7cfb41cc0c77881993cfc212a15bf9775dad3c8be131889b70360117e023b6837b91dad28fc03198080290a08c8089856c753246ff14c7fc3bca38be
diff --git a/app-misc/gramps/gramps-5.1.5.ebuild b/app-misc/gramps/gramps-5.1.5.ebuild
new file mode 100644
index 000000000000..8261bdb45c89
--- /dev/null
+++ b/app-misc/gramps/gramps-5.1.5.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# TODO: py3.10 support (currently blocked by media-libs/gexiv2)
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Community genealogy program aiming to be both intuitive and feature-complete"
+HOMEPAGE="https://gramps-project.org/"
+SRC_URI="https://github.com/gramps-project/${PN}/archive/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="berkdb exif geo postscript +rcs +reports spell test"
+
+RESTRICT="!test? ( test )
+	!berkdb? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.12:3[cairo,${PYTHON_USEDEP}]
+		dev-python/pyicu[${PYTHON_USEDEP}]
+		exif? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection] )
+	')
+	gnome-base/librsvg:2
+	>x11-libs/gtk+-3.14.8:3[introspection]
+	x11-libs/pango[introspection]
+	x11-misc/xdg-utils
+	berkdb? ( $(python_gen_cond_dep '
+		dev-python/bsddb3[${PYTHON_USEDEP}]
+	' python3_{8,9}) )
+	geo? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+	spell? ( app-text/gtkspell:3[introspection] )
+	rcs? ( dev-vcs/rcs )
+	reports? ( media-gfx/graphviz[postscript?] )
+"
+BDEPEND="test? ( ${RDEPEND}
+	$(python_gen_cond_dep '
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.1.3-test_locale.patch
+)
+
+python_prepare_all() {
+	# Install documentation to the proper location. This can't be done
+	# easily with a patch because we substitute in the ${PF} variable,
+	# and that changes with every revision.
+	sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	DISTUTILS_ARGS=(
+		--resourcepath=/usr/share
+		--no-compress-manpages
+	)
+}
+
+python_test() {
+	# Gramps builds just fine out of tree but it confuses its test suite.
+	# The following might be an ugly hack but at least it lets the tests
+	# run properly until either I or upstream have come up with something
+	# better. FIXME: test this when a new release comes out.
+	rm -rf "${S}/build" && ln -s "${BUILD_DIR}" "${S}"/build || \
+		die "Failed to symlink build directory to source directory"
+
+	# Set a sane default locale for the tests which do not explicitly set one.
+	local -x LC_ALL=C.UTF-8
+
+	esetup.py test || die
+}
+
+# Ugly hack to work around Bug #717922
+python_install() {
+	local DISTUTILS_ARGS=(
+		--resourcepath=/usr/share
+		--no-compress-manpages
+		build
+	)
+	distutils-r1_python_install
+	echo -n "${EPREFIX}/usr/share" > "${D}$(python_get_sitedir)/gramps/gen/utils/resource-path" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+
+	if use berkdb; then
+		ewarn "The BSDDB back-end in ${PN} has got known stability and data-corruption issues. It has been deprecated since version 5.1.0 and might be removed in 5.2.0."
+		ewarn "If you have any family trees in this format you are highly advised to convert them to SQLite, as described here:"
+		ewarn
+		ewarn "https://gramps-project.org/wiki/index.php/Gramps_5.1_Wiki_Manual_-_Manage_Family_Trees#Converting_a_BSDDB_Family_Tree_to_SQLite"
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}