app-misc/symlinks: EAPI 6 bump.

Package-Manager: portage-2.3.0

1 files changed, 37 insertions, 0 deletions

diff --git a/app-misc/symlinks/symlinks-1.4-r3.ebuild b/app-misc/symlinks/symlinks-1.4-r3.ebuild
new file mode 100644
index 000000000000..467d0af46d2e
--- /dev/null
+++ b/app-misc/symlinks/symlinks-1.4-r3.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit flag-o-matic eutils toolchain-funcs
+
+DESCRIPTION="Scans for and fixes broken or messy symlinks"
+HOMEPAGE="http://www.ibiblio.org/pub/linux/utils/file/"
+SRC_URI="http://www.ibiblio.org/pub/linux/utils/file/${P}.tar.gz"
+
+LICENSE="freedist"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="static"
+
+DOCS=( symlinks.lsm )
+
+src_prepare() {
+	default
+	# could be useful if being used to repair
+	# symlinks that are preventing shared libraries from
+	# functioning.
+	use static && append-flags -static
+	append-lfs-flags
+	sed 's:-O2::g' -i Makefile || die
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) CFLAGS="${CPPFLAGS} ${CFLAGS} ${LDFLAGS}"
+}
+
+src_install() {
+	dobin "${PN}"
+	doman "${PN}.8"
+}