dev-java/openjdk-jre-bin: bump to 8.222_p10

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

2 files changed, 100 insertions, 0 deletions

diff --git a/dev-java/openjdk-jre-bin/Manifest b/dev-java/openjdk-jre-bin/Manifest
index 6b6003e0823e..98333ee61daa 100644
--- a/dev-java/openjdk-jre-bin/Manifest
+++ b/dev-java/openjdk-jre-bin/Manifest
@@ -1,2 +1,3 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.3_7.tar.gz 41732132 BLAKE2B 9d3bd543fec6eb6c30eabbbb3ca6073365c5b8900dff9af47cfba5569ecfc33a8e2562ed3f8cf4940b2a7d7c427e48164a94fce1f72c8e98fa7f0fc32d923237 SHA512 b7232a3c75a8c4e67f51bd95c8441026b2bfef29cc779768a5f2d300208dc569d672402e06a2d6c6f512450723bc0631c5a18cde80cbc1ec2028c123607df30f
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u212b03.tar.gz 40871242 BLAKE2B 8a6eee7f7465cbccc575e44ab08d6a3d2cedc32954475ea71064a4b6d4379927a795225fed7394922bdaa2a425efb6966d6a0126a55a0fa0e68dc0eeb7a6e935 SHA512 3b0c560cce673fa0e9506c18c4a25b56e26c8ccd7874098f55c37f1a556387b4c2d3ba81ef0368cc666178028eef0fd7beac6307588628c8c8c051381a21366f
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u222b10.tar.gz 40934975 BLAKE2B e03bfb1896e140b79474a4c9004a97aa07bc9fb29c608b2320c05625a56936555ff8ffda7c9656a2d3ff7628bac769e4d14694b2be6d08e4c90b0e6802a05afb SHA512 e1810c4115206cf78c69b971354474098e853c786b472c2140b9e16187efcd3e15bfff26e743e7a532a6f0619f4728482348583662c1eeccd1ebbb82b980f8af
diff --git a/dev-java/openjdk-jre-bin/openjdk-jre-bin-8.222_p10.ebuild b/dev-java/openjdk-jre-bin/openjdk-jre-bin-8.222_p10.ebuild
new file mode 100644
index 000000000000..0b15e6a49cc9
--- /dev/null
+++ b/dev-java/openjdk-jre-bin/openjdk-jre-bin-8.222_p10.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups +gentoo-vm headless-awt nsplugin selinux +webstart"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+PDEPEND="
+	webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+	nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED%/}/${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	dosym "${EPREFIX}"/etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+
+	if use gentoo-vm ; then
+		ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JRE"
+		ewarn "recognised by the system. This will almost certainly break things."
+	else
+		ewarn "The experimental gentoo-vm USE flag has not been enabled so this JRE"
+		ewarn "will not be recognised by the system. For example, simply calling"
+		ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+		ewarn "fully supports OpenJDK 8. This JRE must therefore be invoked using its"
+		ewarn "absolute location under ${EPREFIX}/opt/${P}."
+	fi
+}