proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-libs/check/check-0.9.8-r1.ebuild b/dev-libs/check/check-0.9.8-r1.ebuild
new file mode 100644
index 000000000000..bb35a75b7d75
--- /dev/null
+++ b/dev-libs/check/check-0.9.8-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit autotools autotools-utils eutils
+
+DESCRIPTION="A unit test framework for C"
+HOMEPAGE="http://sourceforge.net/projects/check/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs subunit"
+
+DEPEND="subunit? ( dev-python/subunit )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-0.9.6-AM_PATH_CHECK.patch \
+		"${FILESDIR}"/${PN}-0.9.6-64bitsafe.patch
+
+	sed -i -e '/^docdir =/d' {.,doc}/Makefile.am || die
+
+	# fix out-of-sourcedir build having inconsistent check.h files, for
+	# example breaks USE=subunit.
+	rm src/check.h || die
+
+	# Fix automake warnings being treated as errors, bug #420373
+	sed -i -e s/-Werror// configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-dependency-tracking
+		$(use_enable subunit)
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	dodoc AUTHORS *ChangeLog* NEWS README THANKS TODO
+
+	rm -f "${ED}"/usr/share/doc/${PF}/COPYING* || die
+	find "${ED}" -name '*.la' -exec rm -f {} + || die
+}