dev-libs/keybinder: Version bump

Signed-off-by: Sven Wegener <swegener@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-libs/keybinder/keybinder-0.3.1-r200.ebuild b/dev-libs/keybinder/keybinder-0.3.1-r200.ebuild
new file mode 100644
index 000000000000..ddcf53bdeef2
--- /dev/null
+++ b/dev-libs/keybinder/keybinder-0.3.1-r200.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-single-r1
+
+DESCRIPTION="A library for registering global keyboard shortcuts"
+HOMEPAGE="https://github.com/engla/keybinder"
+SRC_URI="https://github.com/engla/keybinder/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86"
+IUSE="+introspection lua python"
+
+RDEPEND=">=x11-libs/gtk+-2.20:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrender
+	introspection? ( dev-libs/gobject-introspection )
+	lua? ( >=dev-lang/lua-5.1 )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-2.15.3:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="AUTHORS NEWS README"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myconf
+	use lua || myconf='--disable-lua'
+
+	econf \
+		$(use_enable introspection) \
+		$(use_enable python) \
+		${myconf}
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}