dev-libs/libisofs: Version bump to 1.5.0. Switch to EAPI 7.

Signed-off-by: Daniel Pielmeier <billie@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-libs/libisofs/libisofs-1.5.0.ebuild b/dev-libs/libisofs/libisofs-1.5.0.ebuild
new file mode 100644
index 000000000000..6c6df197b20a
--- /dev/null
+++ b/dev-libs/libisofs/libisofs-1.5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Open-source library for reading, mastering and writing optical discs"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wikis/home"
+SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="acl debug static-libs verbose-debug xattr zlib"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	acl? ( virtual/acl )
+	xattr? ( sys-apps/attr )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	econf \
+	$(use_enable static-libs static) \
+	$(use_enable debug) \
+	$(use_enable verbose-debug) \
+	$(use_enable acl libacl) \
+	$(use_enable xattr) \
+	$(use_enable zlib) \
+	--disable-libjte \
+	--disable-ldconfig-at-install
+}
+
+src_install() {
+	default
+
+	dodoc Roadmap doc/{*.txt,Tutorial}
+
+	find "${D}" -name '*.la' -delete || die
+}