dev-libs/liblouis: bump to 3.13.0 with various ebuild fixes

* Use a subslot for liblouis.so soname, as it frequently changes and
  brltty links to it
* BDEPEND on setuptools with USE=python - eclass doesn't do it for
  us because we are DISTUTILS_OPTIONAL=1
* Use proper upstream release tarball, instead of tag snapshot,
  thus removing the need to eautoreconf
* Add automagic libyaml test dependency
* Add support for python 3.7 and 3.8
* Comment why DOCS/HTML_DOCS and einstalldocs are set and done after
  python conditional code, and use default src_install instead of
  emake and einstalldocs separately
* Drop legacy wide-unicode python required use - this was only
  relevant for python2, support of which was dropped in 3.10.0 ebuild
  by now

There is still an automagic dep on texinfo (makeinfo) for building
or not building some documentation, which remains like that, but
can't fix everything at once here.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-libs/liblouis/liblouis-3.13.0.ebuild b/dev-libs/liblouis/liblouis-3.13.0.ebuild
new file mode 100644
index 000000000000..c9ac3b45c4a7
--- /dev/null
+++ b/dev-libs/liblouis/liblouis-3.13.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_OPTIONAL=1
+inherit distutils-r1
+
+DESCRIPTION="An open-source braille translator and back-translator"
+HOMEPAGE="https://github.com/liblouis/liblouis"
+SRC_URI="https://github.com/liblouis/liblouis/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/20"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-apps/help2man
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/setuptools-42.0.2[${PYTHON_USEDEP}]
+	)
+	test? ( dev-libs/libyaml )
+"
+
+src_prepare() {
+	default
+
+	if use python; then
+		pushd python > /dev/null
+		distutils-r1_src_prepare
+		popd > /dev/null
+	fi
+}
+
+src_configure() {
+	econf --enable-ucs4
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd python > /dev/null
+		# setup.py imports liblouis to get the version number,
+		# and this causes the shared library to be dlopened
+		# at build-time.  Hack around it with LD_PRELOAD.
+		# Thanks ArchLinux.
+		LD_PRELOAD+=':../liblouis/.libs/liblouis.so'
+			distutils-r1_src_compile
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	if use python; then
+		pushd python > /dev/null
+		LD_PRELOAD+=':../liblouis/.libs/liblouis.so' \
+			distutils-r1_src_install
+		popd > /dev/null
+	fi
+
+	# These need to be after distutils src_install, or it'll try to install them from under python/ as well
+	DOCS=( README AUTHORS NEWS ChangeLog doc/liblouis.txt )
+	HTML_DOCS=( doc/liblouis.html )
+	default
+}