dev-libs/ocl-icd: install directly into /usr

This leaves x11-drivers/nvidia-drivers as the only OpenCL implementation
still requiring eselect-opencl.

Committed directly due to prolonged absence of the maintainer.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-libs/ocl-icd/ocl-icd-2.2.12-r3.ebuild b/dev-libs/ocl-icd/ocl-icd-2.2.12-r3.ebuild
new file mode 100644
index 000000000000..783021a439e5
--- /dev/null
+++ b/dev-libs/ocl-icd/ocl-icd-2.2.12-r3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby24 ruby25 ruby26 ruby27"
+inherit autotools flag-o-matic multilib-minimal ruby-single
+
+DESCRIPTION="Alternative to vendor specific OpenCL ICD loaders"
+HOMEPAGE="https://github.com/OCL-dev/ocl-icd"
+SRC_URI="https://github.com/OCL-dev/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+khronos-headers"
+
+BDEPEND="${RUBY_DEPS}"
+RDEPEND="!app-eselect/eselect-opencl
+	!dev-libs/opencl-icd-loader
+	!x11-drivers/nvidia-drivers"
+
+PATCHES=("${FILESDIR}"/${P}-gcc-10.patch)
+
+src_prepare() {
+	replace-flags -Os -O2 # bug 646122
+
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf --enable-pthread-once
+}
+
+multilib_src_install() {
+	default
+
+	# Drop .la files
+	find "${ED}" -name '*.la' -delete || die
+
+	# Install vendor headers
+	if use khronos-headers; then
+		insinto /usr/include
+		doins -r "${S}/khronos-headers/CL"
+	fi
+}