dev-perl/Data-Dump-Streamer: -r bump for EAPI7 + Toolchain love

- EAPI7
- Ensure not to break when LD!=CCLD
- Ensure CFLAGS passed to compiler

Bug: https://bugs.gentoo.org/723222
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-perl/Data-Dump-Streamer/Data-Dump-Streamer-2.400.0-r1.ebuild b/dev-perl/Data-Dump-Streamer/Data-Dump-Streamer-2.400.0-r1.ebuild
new file mode 100644
index 000000000000..e94f03a64b8a
--- /dev/null
+++ b/dev-perl/Data-Dump-Streamer/Data-Dump-Streamer-2.400.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=YVES
+DIST_VERSION=2.40
+inherit perl-module
+
+DESCRIPTION="Accurately serialize a data structure as Perl code"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-perl/B-Utils
+	virtual/perl-Data-Dumper
+	virtual/perl-Exporter
+	virtual/perl-IO
+	virtual/perl-IO-Compress
+	virtual/perl-MIME-Base64
+	virtual/perl-Text-Balanced
+	dev-perl/PadWalker
+	virtual/perl-XSLoader
+"
+DEPEND="
+	dev-perl/Module-Build
+"
+BDEPEND="${RDEPEND}
+	dev-perl/Module-Build
+	virtual/perl-Carp
+	virtual/perl-ExtUtils-CBuilder
+	dev-perl/ExtUtils-Depends
+	test? (
+		virtual/perl-Test-Simple
+		dev-perl/JSON-XS
+	)
+"
+PATCHES=( "${FILESDIR}/${P}-perl526.patch" )
+src_prepare() {
+	# Add DDS.pm shortcut
+	echo 'yes' > "${S}"/.answer
+	perl-module_src_prepare
+}
+src_configure() {
+	unset LD
+	[[ -n "${CCLD}" ]] && export LD="${CCLD}"
+	perl-module_src_configure
+}
+src_compile() {
+	./Build --config optimize="${CFLAGS}" build || die
+}