dev-php/symfony-process: bump to v3.4.29

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-php/symfony-process/symfony-process-3.4.29.ebuild b/dev-php/symfony-process/symfony-process-3.4.29.ebuild
new file mode 100644
index 000000000000..75fe9dd83fcc
--- /dev/null
+++ b/dev-php/symfony-process/symfony-process-3.4.29.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="Symfony Process Component"
+HOMEPAGE="https://github.com/symfony/process"
+SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-lang/php:*
+	dev-php/fedora-autoloader"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-php/phpunit )"
+
+S="${WORKDIR}/process-${PV}"
+
+src_prepare() {
+	default
+	if use test; then
+		cp "${FILESDIR}"/autoload.php "${S}"/autoload-test.php || die
+	fi
+}
+
+src_install() {
+	insinto "/usr/share/php/Symfony/Component/Process"
+	doins -r Exception/ Pipes/ ExecutableFinder.php InputStream.php \
+	LICENSE PhpExecutableFinder.php PhpProcess.php ProcessBuilder.php \
+	Process.php ProcessUtils.php "${FILESDIR}"/autoload.php
+	dodoc README.md
+}
+
+src_test() {
+	phpunit --bootstrap "${S}"/autoload-test.php || die "test suite failed"
+}