dev-python/dask-expr: Bump to 1.0.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/dev-python/dask-expr/Manifest b/dev-python/dask-expr/Manifest
index 2e7a31836d90..405afc85cc32 100644
--- a/dev-python/dask-expr/Manifest
+++ b/dev-python/dask-expr/Manifest
@@ -1 +1,2 @@
 DIST dask-expr-1.0.1.gh.tar.gz 233058 BLAKE2B 2e5f64b75e4786e66b6ccab73af8e4a2fa5f7a3dce9cdce801769a2d85d28a0f7657c306f7e8d3458490391dcb9ae967d344832fcd530ef25fd7ee7c747a89b4 SHA512 c779f0e8e8a7a9ed650f58f4900950b72a4915c899dffa2641f707d8db1537213ea67bafc983fb28e50d16e894e8f9d11db9ae77cee9131b273f7aa8e98e6e7c
+DIST dask-expr-1.0.5.gh.tar.gz 239409 BLAKE2B 0fae8540f40cbdead823f300a68df239bb838bb88d34c000b6d29ee451609a4cfc4422586cbf1fc3d2e10b50ffab6e8a2414c14c00635d929d92d7e40b1abff5 SHA512 3baf9e1aca78bc8158bce0e6beb323e511fa5717578bb10bfce27ec38a8f7b6e25b21edeffc669a1ac5f4a987dbbd948bba0f4375f3c5b329d13fab7093708ea
diff --git a/dev-python/dask-expr/dask-expr-1.0.5.ebuild b/dev-python/dask-expr/dask-expr-1.0.5.ebuild
new file mode 100644
index 000000000000..840dbef19952
--- /dev/null
+++ b/dev-python/dask-expr/dask-expr-1.0.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="High Level Expressions for Dask"
+HOMEPAGE="
+	https://github.com/dask/dask-expr/
+	https://pypi.org/project/dask-expr/
+"
+# pypi tarball removes tests, as of 1.0.1
+SRC_URI="
+	https://github.com/dask/dask-expr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/dask-2024.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyarrow-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pandas-2[${PYTHON_USEDEP}]
+"
+# TODO: make pandas depend on pyarrow unconditionally?  we're having
+# transitive deps here.
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-libs/apache-arrow[parquet,snappy]
+		dev-python/pyarrow[parquet,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin
+	sed -i -e '/dask/s:==:>=:' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires distributed
+		'dask_expr/tests/test_shuffle.py::test_respect_context_shuffle[shuffle]'
+	)
+	local EPYTEST_IGNORE=(
+		# requires distributed
+		dask_expr/io/tests/test_parquet.py
+		dask_expr/tests/test_diagnostics.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}