dev-python/dask: Bump to 2023.2.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index 00a0bf3350e7..ceb5003ec1b8 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -2,3 +2,4 @@ DIST dask-2022.12.1.gh.tar.gz 8233697 BLAKE2B 90caeb7a8a9abc03b035c787ae2f26d5da
 DIST dask-2023.1.0.gh.tar.gz 8234373 BLAKE2B 39f4d6336604a66ac769732a36c718b983d2fc37a59276c4140e35354c5c469b5edbff2333ae0b52f3f1462b85ae5c11fc994a99a79330394fff0d7ead14035f SHA512 99650fd2d3805e557ee91bd578e8e4af7f12cc78bbaf72f406d13ff7805591ca0f307d78bb68fdb320dab82da23def01244708e31a87d1a8b5b18dcec8a048fb
 DIST dask-2023.1.1.gh.tar.gz 8497754 BLAKE2B ff9f9f738a557fa0b6a57e0a006fb0c7a29d37c38d4d6ee8656e2e5519a44d7ac6235f106c09c8d28b402bc32909bd065df1cb3d2f9baf8b0ac86bf5ed858969 SHA512 7638a8c8213bec4870bfc1d649bec6ab50354e20df722c3f715b9e438435838253907ead4c13a73d5f1570f63d745059e579274fd0e85c5cdf64411e9d8a761b
 DIST dask-2023.2.0.gh.tar.gz 8499228 BLAKE2B eb8a3345702d8ffd0314963f2d8a358bb28a65be4a3c61efa473514b4eb49baa1a69766a7e71812a13aee72ab6e98298358755c2597a8cafeff12d009fb9f482 SHA512 787f1a9e3c7d27f7fe78c5cd1f6ab0a2c30c36298ec8af4555711cd63018d6d92ed26ef5159cd81b65f1c30c74d24e81c0a2277e00a5cb621b5fd2abff8b3462
+DIST dask-2023.2.1.gh.tar.gz 8514054 BLAKE2B 6f94172cf9f921675fc53cf59e9cbbe211f576374190eecf8e17ad9943bbd1ba15fb002e7cf81f0043b4f2450a0cde7bdb6feb42a08160d0fbaee24d4a2f483a SHA512 1af031fd2992377297daff42c4f706e4e5573cce86a9158ea1fa4f09cf0c8a51ff5fb33d7bc551c16eb0a8e5052e76b32a143b2793027becb4e2367572c46219
diff --git a/dev-python/dask/dask-2023.2.1.ebuild b/dev-python/dask/dask-2023.2.1.ebuild
new file mode 100644
index 000000000000..718d091d9013
--- /dev/null
+++ b/dev-python/dask/dask-2023.2.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="
+	https://www.dask.org/
+	https://github.com/dask/dask/
+	https://pypi.org/project/dask/
+"
+SRC_URI="
+	https://github.com/dask/dask/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-1.2.0[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# more tests relying on -Werror
+	"dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
+	dask/array/tests/test_random.py::test_RandomState_only_funcs
+	# TODO
+	dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
+	dask/tests/test_config.py::test__get_paths
+	dask/array/tests/test_linalg.py::test_solve_assume_a
+	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>0-float-5-1-True]"
+	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>1-float-5-1-True]"
+	# require sqlalchemy<2.0
+	dask/dataframe/io/tests/test_sql.py
+)
+
+src_prepare() {
+	# fails with sqlalchemy-2.0, even though we don't use it x_x
+	sed -i -e '/RemovedIn20Warning/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -p no:flaky -m "not network"
+}