dev-python/graph-tool: add 2.56

Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index ad4b0cbd4170..51e2529f510a 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.46.tar.bz2 15189665 BLAKE2B 85b80feb7019cbd37b4440f6caa97eee4b27e439b2dc865742849e1f4cba9f9090d193fba7de87c84062da4b3f60887e19ee5f33b127373151b7767dacfdd4ae SHA512 a06c2d9acd23a11ea1faf2507222c3c4bfc8973e4fd7185a407d785a43f7409e77ace7af02030106a1bd13ffd719c6c10f7ebb76579448fa9bddd38b9ff7fb2a
+DIST graph-tool-2.56.tar.bz2 15194737 BLAKE2B d28c2056eeeedf37480c042f9b5bfc2fe1f7df35c8f7c69b7431afde9b22fa4b5a79f6e8c8a8d8e9cf48f6607d34472d57c757c32e2c6b8a6c5f7ced79349579 SHA512 4db3711a87067e98095cb2cf49a5a7edb45723ecd238de8b4ff4ca13c34133c5552a29f6b5100e5b8b10a15ec1cac4d0e31578374ed73261d1e18b90980eef1c
diff --git a/dev-python/graph-tool/graph-tool-2.56.ebuild b/dev-python/graph-tool/graph-tool-2.56.ebuild
new file mode 100644
index 000000000000..a856d2584fed
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.56.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}