dev-python/httpx: add 0.22.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 81a5ae729623..a1d1ce6a9251 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1,3 +1,4 @@
 DIST httpx-0.19.0.tar.gz 1667455 BLAKE2B b8d4cb0b6e7f643b62b507930ccf1534d73d93261cab9281ef57d6392f00da325e897d5339aebacfa07aeae8278d3a81b78d6501a1587ffeaef68cc5087bfdaa SHA512 3b327f07d62cf0430672d4f1a4f884618e588496f049522de327f5c34f7260eb21739b7f1fbd6f43a21962bc8737547f3eddbc22751546647f56c9cd7212840a
 DIST httpx-0.21.1.tar.gz 2155133 BLAKE2B c3c800657abaed461ab6f44e3cd9799be4b6499070a5db2ee8d5d61c776d86591c74192eb1c88d4072dc361ea4c9448a3ed061c715fa4504fc931fdd96ccde62 SHA512 a4f737f6c6ae909fd3ea811e0ff3b78ed6496da8d797ef49746f744216e055f8225d613fe935d5e2780aa1b233053ad436e8849eef578e662ca8ee34513ad12e
 DIST httpx-0.21.3.tar.gz 2157078 BLAKE2B 08a9328a7350534abe646f0bf60bd15600a1cb3eb8d06578c87ed9a7d4e55efdddd2be597650cddec9f6456e89a1b159f3e23aa657f379f78157c12670cdadb0 SHA512 0a551de52954db5ed2c33d1b5c172607516031a7c86c0f235bd04f12f4cf82f63980a9f53115dac801748b0c282890b3ed4a53b2c912adbd245c10ad61dbf67e
+DIST httpx-0.22.0.gh.tar.gz 2157682 BLAKE2B bb08a7c4b72478d24264c0dca5630205ff386af73294dca66dcd12b646de602ad64e308feedaabd58742cb7a9d799fa23cd2f922e685e74f8181e1b5e9f1c4ee SHA512 a7360f5355f75f07425b42d49697e480319f3fe606d4601bb6d64b870c8a8fce6fad8bd857ef422fc48e6141201307ee94876d5bc54a68557c7dc32ce8f1451b
diff --git a/dev-python/httpx/httpx-0.22.0.ebuild b/dev-python/httpx/httpx-0.22.0.ebuild
new file mode 100644
index 000000000000..6cc05440c2be
--- /dev/null
+++ b/dev-python/httpx/httpx-0.22.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Docs builder mkdocs not keyworded on all these arches yet
+# DOCS_BUILDER="mkdocs"
+# DOCS_DEPEND="dev-python/mkdocs-material"
+# DOCS_AUTODOC=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 optfeature # docs
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="https://www.python-httpx.org/"
+SRC_URI="
+	https://github.com/encode/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/charset_normalizer[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	=dev-python/httpcore-0.14*[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.3[${PYTHON_USEDEP}]
+	<dev-python/rfc3986-2[${PYTHON_USEDEP}]
+	cli? (
+		=dev-python/click-8*[${PYTHON_USEDEP}]
+		=dev-python/pygments-2*[${PYTHON_USEDEP}]
+		=dev-python/rich-10*[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/h2[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-trio[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if ! use cli; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/client/test_proxies.py::test_async_proxy_close
+		tests/client/test_proxies.py::test_sync_proxy_close
+
+		# Result change in charset-normalizer-2.0.7+
+		'tests/test_decoders.py::test_text_decoder[data3-iso-8859-1]'
+		'tests/models/test_responses.py::test_response_no_charset_with_iso_8859_1_content'
+	)
+	local EPYTEST_IGNORE=()
+
+	use cli || EPYTEST_IGNORE+=(
+		tests/test_main.py
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "HTTP/2 support" dev-python/h2
+	optfeature "SOCKS proxy support" dev-python/socksio
+	optfeature "Decoding for brotli compressed responses" dev-python/brotlicffi
+}