dev-python/python-neutronclient: Bump to 7.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index 0fa483400ff3..25e8e5b300be 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -1 +1,2 @@
 DIST python-neutronclient-7.7.0.tar.gz 304440 BLAKE2B 391ecdfe4f4df927c0c626ca644543b9ef4a3a926cfb9bdc68676836185898a141d9fc60277ee4ddf61336eec785656f45ffd2bb74cf9b6250f2b1934883f870 SHA512 ecd6bc4e229f992b9a320d247f5af89e819c308f9360d5f86c297d4daf634498e4a2f3953e5713bef06ac17cce37e86d2b0a4ff1ba3178e78fc082a148eeac8e
+DIST python-neutronclient-7.8.0.tar.gz 304872 BLAKE2B 780e1b2942a43bca93888683d1c2e713cfc0927d49135004a6f6d42dff7962def6b0fc7f308b75b4392f4fb5df4d26fcea107b9006d4ba957c0d76294395e5c9 SHA512 3022d79348334632ab3afa142aab11e424b168a4ba04223722da80e59de2695b477c2d829bb14a37e7baf387f9d63b8c4456fc5712f8d591d3de51fad76d6c78
diff --git a/dev-python/python-neutronclient/python-neutronclient-7.8.0.ebuild b/dev-python/python-neutronclient/python-neutronclient-7.8.0.ebuild
new file mode 100644
index 000000000000..cec11e07b62c
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-7.8.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.5.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslotest[${PYTHON_USEDEP}]
+		dev-python/python-openstackclient[${PYTHON_USEDEP}]
+		dev-python/subunit[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Needs osprofile
+	rm neutronclient/tests/unit/test_http.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b neutronclient.tests.unit
+}
+
+python_install() {
+	distutils-r1_python_install
+	#stupid stupid
+	local SITEDIR="${D}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.egg-info )
+	#[[ -f ${egg[0]} ]] || die "python_quantumclient*.egg-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}