dev-python/pythondialog: Add version that supports python2

Package-Manager: portage-2.2.26

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/pythondialog/pythondialog-3.3.0-r200.ebuild b/dev-python/pythondialog/pythondialog-3.3.0-r200.ebuild
new file mode 100644
index 000000000000..e1f504e90667
--- /dev/null
+++ b/dev-python/pythondialog/pythondialog-3.3.0-r200.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python module for making simple text/console-mode user interfaces"
+HOMEPAGE="http://pythondialog.sourceforge.net/ https://pypi.python.org/pypi/python2-pythondialog"
+SRC_URI="mirror://pypi/${PN:0:1}/python2-${PN}/python2-${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="python-2"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
+IUSE="doc examples"
+
+RDEPEND="dev-util/dialog"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/python2-${P}
+
+python_prepare_all() {
+	sed -e "/^    'sphinx.ext.intersphinx',/d" -i doc/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}