dev-python/tox: Bump to 4.0.16

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index c44ddc31b0f8..5fc4969470da 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -4,3 +4,4 @@ DIST tox-4.0.12.gh.tar.gz 282817 BLAKE2B 7237f33086c9e0147457bf46db47f6b4e6fcaf3
 DIST tox-4.0.13.gh.tar.gz 283017 BLAKE2B 2bf55f1514cbc1806404f4106b2af701f28698da0fd9789a71d582612b7eeb2356d15b26a9dd0e663b19cdcb90e975138c15cd80ee5f10c261a8b203bef0d830 SHA512 a08139b490ab2e967cb9fdb9ffb290fa1dcce3102d41b07fdfd566f9d270873d6371229dacae5e00a4816bf37eb7cca12bae0948e5b4e6c1879e96b444070d4b
 DIST tox-4.0.14.gh.tar.gz 283154 BLAKE2B 8701f25b00152c283503f082765e28b46f2c01b01bc86129dee6b28fd623bb2ae2c2726401b69e278edbc4fffbaad672aa02504870a1c05ec965a819dc812933 SHA512 3ed0a80b438ac11804b56f6b55a504c0246b0a8cfa9bb4fa8246758bd942ac0b0b5c203e89069303faa47a2dcd009ea81ef9f8e3e38e6d9a30dd4f05c0b79510
 DIST tox-4.0.15.gh.tar.gz 283422 BLAKE2B 7efe3d50d0d08ba32f462e8d533ed97779e65c3830ae3af211dbb164828bcb1158cf0cc8581aa2dc727aea595b2e942a5c581c310b9afe8384a711e53a38d9a9 SHA512 5232abc6f7824a576bb40d2615c0c90a189a516faa9089cc7e3d1eadebe95e44cbcbb02792c0b34753448b8269f0b6035c2755c2d3bd48a49aa1b656db6d57f7
+DIST tox-4.0.16.gh.tar.gz 283676 BLAKE2B b9b8149dcfa141518cb18a0ac3263c65f4928fc068357d7a513971d7037cc60cb4b3627d61d3e3479622b9fcbdc235356ca97cde993ab47db7abf4755854b17d SHA512 db4428b576dd3b669969b2390203ba6a0efa85f60073374b32c7ff1273745dde59ef0ffd404a7db98ca9056c5d5b5bd1811b51af7b475c116816c150c4d88c4c
diff --git a/dev-python/tox/tox-4.0.16.ebuild b/dev-python/tox/tox-4.0.16.ebuild
new file mode 100644
index 000000000000..533a8c9ff12d
--- /dev/null
+++ b/dev-python/tox/tox-4.0.16.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
+
+	epytest
+}