dev-qt/qtwayland: Drop USE libinput

USE -libinput is broken with dev-qt/qtgui[-libinput,X], would also need -X.

Closes: https://bugs.gentoo.org/711476
Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-qt/qtwayland/qtwayland-5.14.1-r2.ebuild b/dev-qt/qtwayland/qtwayland-5.14.1-r2.ebuild
new file mode 100644
index 000000000000..391ab67ae43e
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.14.1-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="vulkan X"
+
+DEPEND="
+	>=dev-libs/wayland-1.6.0
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}[egl,libinput,vulkan=]
+	media-libs/mesa[egl]
+	>=x11-libs/libxkbcommon-0.2.0
+	vulkan? ( dev-util/vulkan-headers )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcomposite
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	use X || rm -r config.tests/xcomposite || die
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use vulkan feature-wayland-vulkan-server-buffer)
+		$(qt_use X feature-xcomposite-egl)
+		$(qt_use X feature-xcomposite-glx)
+	)
+	qt5-build_src_configure
+}