dev-ruby/actionmailbox: add 6.0.6.1

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-ruby/actionmailbox/actionmailbox-6.0.6.1.ebuild b/dev-ruby/actionmailbox/actionmailbox-6.0.6.1.ebuild
new file mode 100644
index 000000000000..7503a5d4c9d8
--- /dev/null
+++ b/dev-ruby/actionmailbox/actionmailbox-6.0.6.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby27 ruby30"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="actionmailbox.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_EXTRAINSTALL="app config db"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Framework for designing email-service layers"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/actionpack-${PV}
+	~dev-ruby/activejob-${PV}
+	~dev-ruby/activerecord-${PV}
+	~dev-ruby/activestorage-${PV}
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/mail-2.7.1:*
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/bundler
+	<dev-ruby/mail-2.8
+	dev-ruby/mocha
+
+)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|sass-rails\|webpacker\|rubocop\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\|websocket-client-simple\|libxml-ruby\|redis\|blade\|aws-sdk\|google-cloud\|azure-storage\|selenium\|webdrivers\|minitest-bisect\|minitest-retry\|minitest-reporters\|listen\|rack-cache\|capybara\|webpacker\|bootsnap\|byebug\|dalli\)/ s:^:#:" \
+		-e '/minitest/ s/5.15/5.16/' \
+		-e '10igem "mail", "< 2.8"' \
+		-e '/:job/,/end/ s:^:#:' \
+		-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
+	rm ../Gemfile.lock || die
+	sed -i -e '/byebug/ s:^:#:' test/test_helper.rb || die
+}
+
+each_ruby_prepare() {
+	sed -i -e 's:ruby:'${RUBY}':' test/dummy/bin/* || die
+}