dev-ruby/actionpack: allow all rack 2 versions

Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

2 files changed, 126 insertions, 0 deletions

diff --git a/dev-ruby/actionpack/actionpack-5.2.4.3-r1.ebuild b/dev-ruby/actionpack/actionpack-5.2.4.3-r1.ebuild
new file mode 100644
index 000000000000..c90f763ca990
--- /dev/null
+++ b/dev-ruby/actionpack/actionpack-5.2.4.3-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem eapi7-ver
+
+DESCRIPTION="Eases web-request routing, handling, and response"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	~dev-ruby/actionview-${PV}
+	|| ( dev-ruby/rack:2.2 dev-ruby/rack:2.1 >=dev-ruby/rack-2.0.8:2.0 )
+	>=dev-ruby/rack-test-0.6.3:*
+	>=dev-ruby/rails-html-sanitizer-1.0.2:1
+	dev-ruby/rails-dom-testing:2
+"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/mocha:0.14
+		dev-ruby/bundler
+		>=dev-ruby/capybara-2.15
+		~dev-ruby/activemodel-${PV}
+		>=dev-ruby/rack-cache-1.2:1.2
+		www-servers/puma
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\)/ s:^:#:" \
+		-e '/:job/,/end/ s:^:#:' \
+		-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
+	rm ../Gemfile.lock || die
+
+	sed -e '1i gem "activemodel", "~> 5.2.0"' \
+		-e '1i gem "actionview", "~> 5.2.0"' \
+		-e '1i gem "railties", "~> 5.2.0"' \
+		-i test/abstract_unit.rb || die
+
+	# Use different timezone notation, this changed at some point due to an external dependency changing.
+	sed -i -e 's/-0000/GMT/' test/dispatch/response_test.rb test/dispatch/cookies_test.rb test/dispatch/session/cookie_store_test.rb || die
+
+	# Avoid broken tests already fixed upstream
+	sed -i -e '/cookie syntax resilience/askip "broken test"' test/dispatch/request_test.rb || die
+	sed -i -e '/test_keeps_original_headers_behavior/askip "broken test"' test/dispatch/ssl_test.rb || die
+}
diff --git a/dev-ruby/actionpack/actionpack-6.0.3.2-r1.ebuild b/dev-ruby/actionpack/actionpack-6.0.3.2-r1.ebuild
new file mode 100644
index 000000000000..b9f96b9946de
--- /dev/null
+++ b/dev-ruby/actionpack/actionpack-6.0.3.2-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Eases web-request routing, handling, and response"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	~dev-ruby/actionview-${PV}
+	|| ( dev-ruby/rack:2.2 dev-ruby/rack:2.1 >=dev-ruby/rack-2.0.8:2.0 )
+	>=dev-ruby/rack-test-0.6.3:*
+	>=dev-ruby/rails-html-sanitizer-1.2.0:1
+	dev-ruby/rails-dom-testing:2
+"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/mocha:0.14
+		dev-ruby/bundler
+		>=dev-ruby/capybara-2.15
+		~dev-ruby/activemodel-${PV}
+		~dev-ruby/railties-${PV}
+		>=dev-ruby/rack-cache-1.2:1.2
+		www-servers/puma
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\)/ s:^:#:" \
+		-e '/:job/,/end/ s:^:#:' \
+		-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
+	rm ../Gemfile.lock || die
+
+	# Use different timezone notation, this changed at some point due to an external dependency changing.
+	sed -i -e 's/-0000/GMT/' test/dispatch/response_test.rb test/dispatch/cookies_test.rb test/dispatch/session/cookie_store_test.rb || die
+}