dev-tcltk/tktray: fix tclconfig path

Tcl is multilib, who knew!

Closes: https://bugs.gentoo.org/874870
Bug: https://bugs.gentoo.org/874852
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-tcltk/tktray/tktray-1.3.9-r2.ebuild b/dev-tcltk/tktray/tktray-1.3.9-r2.ebuild
new file mode 100644
index 000000000000..db484aefe6cd
--- /dev/null
+++ b/dev-tcltk/tktray/tktray-1.3.9-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="System Tray Icon Support for Tk on X11"
+HOMEPAGE="https://code.google.com/p/tktray/"
+SRC_URI="https://tktray.googlecode.com/files/${PN}${PV}.tar.gz"
+S="${WORKDIR}/${PN}${PV}"
+
+LICENSE="tcltk"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~sparc x86"
+IUSE="debug threads"
+
+# tests need actual X server with user interaction, bug #284919
+RESTRICT="test"
+
+DEPEND="
+	>=dev-lang/tcl-8.4:=
+	>=dev-lang/tk-8.4:=
+	x11-libs/libXext"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/1.1-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	# Fix bad configure tests w/ Clang 16
+	eautoreconf
+}
+
+src_configure() {
+	source "${ESYSROOT}/usr/$(get_libdir)/tclConfig.sh" || die
+
+	CPPFLAGS="-I${TCL_SRC_DIR}/generic ${CPPFLAGS}" \
+	econf \
+		$(use_enable debug symbols) \
+		$(use_enable threads)
+}