games-action/lugaru: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1

4 files changed, 80 insertions, 19 deletions

diff --git a/games-action/lugaru/files/lugaru-20151204-dir.patch b/games-action/lugaru/files/lugaru-20151204-dir.patch
index 8595084232ff..da9310dde58e 100644
--- a/games-action/lugaru/files/lugaru-20151204-dir.patch
+++ b/games-action/lugaru/files/lugaru-20151204-dir.patch
@@ -1,5 +1,5 @@
---- Source/OpenGL_Windows.cpp.orig	2015-01-14 23:57:19.799186785 -0500
-+++ Source/OpenGL_Windows.cpp	2015-01-14 23:57:36.022643953 -0500
+--- a/Source/OpenGL_Windows.cpp	2015-01-14 23:57:19.799186785 -0500
++++ b/Source/OpenGL_Windows.cpp	2015-01-14 23:57:36.022643953 -0500
 @@ -1330,7 +1330,7 @@
  
      // !!! FIXME: we could use a Win32 API for this.  --ryan.
diff --git a/games-action/lugaru/files/lugaru-9999-dir.patch b/games-action/lugaru/files/lugaru-9999-dir.patch
index 8595084232ff..da9310dde58e 100644
--- a/games-action/lugaru/files/lugaru-9999-dir.patch
+++ b/games-action/lugaru/files/lugaru-9999-dir.patch
@@ -1,5 +1,5 @@
---- Source/OpenGL_Windows.cpp.orig	2015-01-14 23:57:19.799186785 -0500
-+++ Source/OpenGL_Windows.cpp	2015-01-14 23:57:36.022643953 -0500
+--- a/Source/OpenGL_Windows.cpp	2015-01-14 23:57:19.799186785 -0500
++++ b/Source/OpenGL_Windows.cpp	2015-01-14 23:57:36.022643953 -0500
 @@ -1330,7 +1330,7 @@
  
      // !!! FIXME: we could use a Win32 API for this.  --ryan.
diff --git a/games-action/lugaru/lugaru-20151204-r1.ebuild b/games-action/lugaru/lugaru-20151204-r1.ebuild
new file mode 100644
index 000000000000..576d94bac4c3
--- /dev/null
+++ b/games-action/lugaru/lugaru-20151204-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils cmake-utils
+
+DESCRIPTION="3D arcade with unique fighting system and anthropomorphic characters"
+HOMEPAGE="https://bitbucket.org/osslugaru/lugaru/wiki/Home"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2+ free-noncomm CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	media-libs/libpng:0
+	media-libs/libsdl[opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	sys-libs/zlib
+	virtual/glu
+	virtual/jpeg:0
+	virtual/opengl"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-dir.patch"
+)
+
+src_prepare() {
+	default
+	sed -i \
+		-e "s:@GENTOO_DIR@:/usr/share/${PN}:" \
+		Source/OpenGL_Windows.cpp || die
+}
+
+src_configure() {
+	mycmakeargs=(
+		"-DCMAKE_VERBOSE_MAKEFILE=TRUE"
+		"-DLUGARU_FORCE_INTERNAL_OPENGL=False"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	dobin "${WORKDIR}/${P}_build/lugaru"
+	insinto /usr/share/${PN}
+	doins -r Data/
+	newicon Source/win-res/Lugaru.png ${PN}.png
+	make_desktop_entry ${PN} Lugaru ${PN}
+}
diff --git a/games-action/lugaru/lugaru-9999.ebuild b/games-action/lugaru/lugaru-9999.ebuild
index 2c42553fdb8f..7aa42ee9c090 100644
--- a/games-action/lugaru/lugaru-9999.ebuild
+++ b/games-action/lugaru/lugaru-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
-inherit eutils cmake-utils mercurial games
+EAPI=6
+inherit eutils cmake-utils mercurial
 
 EHG_REPO_URI="https://bitbucket.org/osslugaru/lugaru/"
 DESCRIPTION="3D arcade with unique fighting system and anthropomorphic characters"
@@ -16,14 +16,14 @@ KEYWORDS=""
 IUSE=""
 
 RDEPEND="
-	virtual/glu
-	virtual/opengl
 	media-libs/libsdl[opengl,video]
-	media-libs/openal
+	media-libs/libpng:0
 	media-libs/libvorbis
+	media-libs/openal
+	sys-libs/zlib
+	virtual/glu
 	virtual/jpeg:0
-	media-libs/libpng:0
-	sys-libs/zlib"
+	virtual/opengl"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
@@ -31,11 +31,15 @@ src_unpack() {
 	mercurial_src_unpack
 }
 
+PATCHES=(
+    "${FILESDIR}/${P}-dir.patch"
+)
+
 src_prepare() {
-	epatch "${FILESDIR}/${P}-dir.patch"
-	sed -i \
-		-e "s:@GENTOO_DIR@:${GAMES_DATADIR}/${PN}:" \
-		Source/OpenGL_Windows.cpp || die
+    default
+    sed -i \
+        -e "s:@GENTOO_DIR@:/usr/share/${PN}:" \
+        Source/OpenGL_Windows.cpp || die
 }
 
 src_configure() {
@@ -51,10 +55,9 @@ src_compile() {
 }
 
 src_install() {
-	dogamesbin "${WORKDIR}/${P}_build/lugaru"
-	insinto "${GAMES_DATADIR}/${PN}"
+	dobin "${WORKDIR}/${P}_build/lugaru"
+	insinto /usr/share/${PN}
 	doins -r Data/
 	newicon Source/win-res/Lugaru.png ${PN}.png
 	make_desktop_entry ${PN} Lugaru ${PN}
-	prepgamesdirs
 }