games-server/crossfire-server: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9

1 files changed, 51 insertions, 0 deletions

diff --git a/games-server/crossfire-server/crossfire-server-1.71.0-r1.ebuild b/games-server/crossfire-server/crossfire-server-1.71.0-r1.ebuild
new file mode 100644
index 000000000000..3012afe88c9b
--- /dev/null
+++ b/games-server/crossfire-server/crossfire-server-1.71.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P="${P/-server/}"
+DESCRIPTION="Server for the crossfire clients"
+HOMEPAGE="http://crossfire.real-time.com/"
+SRC_URI="mirror://sourceforge/crossfire/${PN}/${PV}/${MY_P}.tar.bz2
+	mirror://sourceforge/crossfire/${PN}/${PV}/${MY_P}.maps.tar.bz2
+	mirror://sourceforge/crossfire/${PN}/${PV}/${MY_P}.arch.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X"
+RESTRICT="test"
+
+RDEPEND="
+	net-misc/curl
+	X? (
+		x11-libs/libXaw
+		media-libs/libpng:0=
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	rm -f "${WORKDIR}"/maps/Info/combine.pl # bug #236205
+	ln -s "${WORKDIR}/arch" "${S}/lib" || die
+	eapply "${FILESDIR}"/${P}-format.patch
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	# work around the collect.pl locking
+	emake -j1 -C lib
+	emake
+}
+
+src_install() {
+	default
+	keepdir /var/lib/crossfire/{account,datafiles,maps,players,template-maps,unique-items}
+	insinto /usr/share/crossfire
+	doins -r "${WORKDIR}/maps"
+	find "${D}" -name '*.la' -delete || die
+}