proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 97 insertions, 0 deletions

diff --git a/games-strategy/freeorion/freeorion-0.4.5_pre.ebuild b/games-strategy/freeorion/freeorion-0.4.5_pre.ebuild
new file mode 100644
index 000000000000..66e982968d7c
--- /dev/null
+++ b/games-strategy/freeorion/freeorion-0.4.5_pre.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+inherit cmake-utils python-any-r1 games
+
+DESCRIPTION="A free turn-based space empire and galactic conquest game"
+HOMEPAGE="http://www.freeorion.org"
+SRC_URI="http://dev.gentoo.org/~tomka/files/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cg"
+
+# Needs it's own version of GG(dev-games/gigi) which it ships.
+# The split version dev-games/gigi is not used anymore as of 0.4.3
+RDEPEND="
+	!dev-games/gigi
+	media-libs/libsdl2
+	>=dev-libs/boost-1.47[python]
+	media-libs/freealut
+	media-libs/glew
+	media-libs/libogg
+	media-libs/libsdl[X,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	sci-physics/bullet
+	sys-libs/zlib
+	virtual/opengl"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig"
+
+CMAKE_USE_DIR="${S}"
+CMAKE_VERBOSE="1"
+
+pkg_setup() {
+	# build system is using FindPythonLibs.cmake which needs python:2
+	python-any-r1_pkg_setup
+	games_pkg_setup
+}
+
+src_prepare() {
+
+	epatch "${FILESDIR}/${P}-boost-1.57.patch"
+	epatch "${FILESDIR}/${P}-boost-1.58.patch"
+
+	# parse subdir sets -O3
+	sed -e "s:-O3::" -i parse/CMakeLists.txt
+
+	# set revision for display in game -- update on bump!
+	sed -i -e 's/???/8051/' CMakeLists.txt
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DRELEASE_COMPILE_FLAGS=""
+		-DCMAKE_SKIP_RPATH=ON
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	# data files
+	rm "${CMAKE_USE_DIR}"/default/COPYING || die
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r "${CMAKE_USE_DIR}"/default || die
+
+	# bin
+	dogamesbin "${CMAKE_BUILD_DIR}"/${PN}{ca,d} || die
+	newgamesbin "${CMAKE_BUILD_DIR}"/${PN} ${PN}.bin || die
+	games_make_wrapper ${PN} \
+		"${GAMES_BINDIR}/${PN}.bin --resource-dir ${GAMES_DATADIR}/${PN}/default" \
+		"${GAMES_DATADIR}/${PN}"
+
+	# lib
+	dogameslib "${CMAKE_BUILD_DIR}"/libfreeorion{common,parse}.so || die
+	dogameslib "${CMAKE_BUILD_DIR}"/libGiGi*.so || die
+
+	# other
+	dodoc "${CMAKE_USE_DIR}"/changelog.txt || die
+	newicon "${CMAKE_USE_DIR}"/default/data/art/icons/FO_Icon_32x32.png \
+		${PN}.png || die
+	make_desktop_entry ${PN} ${PN} ${PN}
+
+	# permissions
+	prepgamesdirs
+}